mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
38d94c34a1
zstd is dual-licensed under BSD _OR_ GPLv2. License wording in the README for v1.5.5 is misleading, but license headers in the code clearly state that there is a choice between the two licenses. (From OE-Core rev: 40f85de590c188c9c3985e64a83efaf06b0b4fbc) Signed-off-by: Massimiliano Minella <massimiliano.minella@se.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
48 lines
1.6 KiB
BlitzBasic
48 lines
1.6 KiB
BlitzBasic
SUMMARY = "Zstandard - Fast real-time compression algorithm"
|
|
DESCRIPTION = "Zstandard is a fast lossless compression algorithm, targeting \
|
|
real-time compression scenarios at zlib-level and better compression ratios. \
|
|
It's backed by a very fast entropy stage, provided by Huff0 and FSE library."
|
|
HOMEPAGE = "http://www.zstd.net/"
|
|
SECTION = "console/utils"
|
|
|
|
LICENSE = "BSD-3-Clause | GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=0822a32f7acdbe013606746641746ee8 \
|
|
file://COPYING;md5=39bba7d2cf0ba1036f2a6e2be52fe3f0 \
|
|
"
|
|
|
|
SRC_URI = "git://github.com/facebook/zstd.git;branch=release;protocol=https \
|
|
file://0001-pzstd-use-directly-for-the-test-c-snippet.patch"
|
|
|
|
SRCREV = "63779c798237346c2b245c546c40b72a5a5913fe"
|
|
UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+(\.\d+)+)"
|
|
|
|
CVE_PRODUCT = "zstandard"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[lz4] = "HAVE_LZ4=1,HAVE_LZ4=0,lz4"
|
|
PACKAGECONFIG[lzma] = "HAVE_LZMA=1,HAVE_LZMA=0,xz"
|
|
PACKAGECONFIG[zlib] = "HAVE_ZLIB=1,HAVE_ZLIB=0,zlib"
|
|
|
|
# See programs/README.md for how to use this
|
|
ZSTD_LEGACY_SUPPORT ??= "4"
|
|
|
|
EXTRA_OEMAKE += "V=1"
|
|
|
|
do_compile () {
|
|
oe_runmake ${PACKAGECONFIG_CONFARGS} ZSTD_LEGACY_SUPPORT=${ZSTD_LEGACY_SUPPORT}
|
|
oe_runmake ${PACKAGECONFIG_CONFARGS} ZSTD_LEGACY_SUPPORT=${ZSTD_LEGACY_SUPPORT} -C contrib/pzstd
|
|
}
|
|
|
|
do_install () {
|
|
oe_runmake install 'DESTDIR=${D}'
|
|
oe_runmake install 'DESTDIR=${D}' PREFIX=${prefix} -C contrib/pzstd
|
|
}
|
|
|
|
PACKAGE_BEFORE_PN = "libzstd"
|
|
|
|
FILES:libzstd = "${libdir}/libzstd${SOLIBS}"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|