mirror of
https://git.yoctoproject.org/poky
synced 2026-02-16 05:33:03 +01:00
c13eb4ff7c
The current definition for ARM_THUMB_SUFFIX doesn't consider armv8 and will therefore cause TUNE_PKGARCH to be set incorrectly for machines which inherit arch-armv8 and don't include aarch64 in TUNE_FEATURES (ie when building for 32bit ARMv8). Also fix typo in comments and improve TUNEVALID[thumb] wording. (From OE-Core rev: 3691fd7dbe7f01ca29c14fc603c6946864af3b3c) Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
31 lines
1.4 KiB
PHP
31 lines
1.4 KiB
PHP
|
|
TUNEVALID[thumb] = "Support Thumb instructions"
|
|
|
|
ARM_THUMB_SUFFIX = "${@bb.utils.contains_any('TUNE_FEATURES', 'armv4 armv5 armv6', 't', 't2', d)}"
|
|
|
|
# If the device supports ARM, then respect ARM_THUMB_OPT (which can be "arm" or "thumb")
|
|
# If the device doesn't support ARM, then always set "thumb" even when
|
|
# some recipe explicitly sets ARM_INSTRUCTION_SET to "arm"
|
|
ARM_THUMB_OPT = "${@['arm', 'thumb'][d.getVar('ARM_INSTRUCTION_SET') == 'thumb']}"
|
|
ARM_M_OPT = "${@bb.utils.contains('TUNE_FEATURES', 'arm', '${ARM_THUMB_OPT}', 'thumb', d)}"
|
|
|
|
python () {
|
|
if bb.utils.contains('TUNE_FEATURES', 'thumb', False, True, d):
|
|
return
|
|
selected = d.getVar('ARM_INSTRUCTION_SET')
|
|
if selected == None:
|
|
return
|
|
used = d.getVar('ARM_M_OPT')
|
|
if selected != used:
|
|
pn = d.getVar('PN')
|
|
bb.warn("Recipe '%s' selects ARM_INSTRUCTION_SET to be '%s', but tune configuration overrides it to '%s'" % (pn, selected, used))
|
|
}
|
|
|
|
TUNE_CCARGS .= "${@bb.utils.contains('TUNE_FEATURES', 'thumb', ' -m${ARM_M_OPT}', '', d)}"
|
|
|
|
# Add suffix from ARM_THUMB_SUFFIX only if after all this we still set ARM_M_OPT to thumb
|
|
ARMPKGSFX_THUMB .= "${@bb.utils.contains('TUNE_FEATURES', 'thumb', '${ARM_THUMB_SUFFIX}', '', d) if d.getVar('ARM_M_OPT') == 'thumb' else ''}"
|
|
|
|
# what about armv7m devices which don't support -marm (e.g. Cortex-M3)?
|
|
TARGET_CC_KERNEL_ARCH += "${@bb.utils.contains('TUNE_FEATURES', 'thumb', '-mno-thumb-interwork -marm', '', d)}"
|