mirror of
https://git.yoctoproject.org/poky
synced 2026-02-15 21:23:04 +01:00
b8b1edbe6c
The default of EXTRA_OEMAKE is already empty since commit: OE-Core rev: aeb653861a0ec39ea7a014c0622980edcbf653fa bitbake.conf: Remove unhelpful default value for EXTRA_OEMAKE (From OE-Core rev: 4c1d679a0fd601ba37ab37b11f660cc41d8507ff) Signed-off-by: Stefan Müller-Klieser <s.mueller-klieser@phytec.de> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.1 KiB
BlitzBasic
41 lines
1.1 KiB
BlitzBasic
SUMMARY = "UProbes kernel module for SystemTap"
|
|
|
|
require systemtap_git.inc
|
|
|
|
DEPENDS = "systemtap virtual/kernel"
|
|
|
|
# On systems without CONFIG_UTRACE, this package is empty.
|
|
ALLOW_EMPTY_${PN} = "1"
|
|
|
|
inherit module-base gettext
|
|
|
|
FILESEXTRAPATHS =. "${FILE_DIRNAME}/systemtap:"
|
|
|
|
FILES_${PN} += "${datadir}/systemtap/runtime/uprobes"
|
|
|
|
# Compile and install the uprobes kernel module on machines with utrace
|
|
# support. Note that staprun expects it in the systemtap/runtime directory,
|
|
# not in /lib/modules.
|
|
do_compile() {
|
|
if grep -q "CONFIG_UTRACE=y" ${STAGING_KERNEL_BUILDDIR}/.config
|
|
then
|
|
unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS CC LD CPP
|
|
oe_runmake CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
|
|
AR="${KERNEL_AR}" \
|
|
-C ${STAGING_KERNEL_DIR} scripts
|
|
oe_runmake KDIR=${STAGING_KERNEL_DIR} \
|
|
M="${S}/runtime/uprobes/" \
|
|
CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
|
|
AR="${KERNEL_AR}" \
|
|
-C "${S}/runtime/uprobes/"
|
|
fi
|
|
}
|
|
|
|
do_install() {
|
|
if [ -e "${S}/runtime/uprobes/uprobes.ko" ]
|
|
then
|
|
install -d ${D}${datadir}/systemtap/runtime/uprobes/
|
|
install -m 0644 ${S}/runtime/uprobes/uprobes.ko ${D}${datadir}/systemtap/runtime/uprobes/
|
|
fi
|
|
}
|