mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 18:32:13 +02:00
99bb209520
file-native when built on a Debian 10 host will embed a dependency to
'libbz2.so.1.0' (instead of 'libbz2.so.1'). This can cause issues
when sharing the sstate between hosts e.g.:
recipe-sysroot-native/usr/lib/rpm/rpmdeps:
error while loading shared libraries: libbz2.so.1.0: \
cannot open shared object file: No such file or directory
To avoid this situation, let's add the bzip2-replacement-native to the
file recipe's DEPENDS_class-native .
Details in https://bugzilla.yoctoproject.org/show_bug.cgi?id=13915 .
(From OE-Core rev: 5a2bc3bfa9e1a4f37b6e26a5c40a4a9c025d03f1)
Signed-off-by: Jan-Simon Moeller <dl9pf@gmx.de>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
(cherry picked from commit 4a996574464028bd5d57b90920d0887d1a81e9e9)
Signed-off-by: Steve Sakoman <steve@sakoman.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
56 lines
1.7 KiB
BlitzBasic
56 lines
1.7 KiB
BlitzBasic
SUMMARY = "File classification tool"
|
|
DESCRIPTION = "File attempts to classify files depending \
|
|
on their contents and prints a description if a match is found."
|
|
HOMEPAGE = "http://www.darwinsys.com/file/"
|
|
SECTION = "console/utils"
|
|
|
|
# two clause BSD
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;beginline=2;md5=0251eaec1188b20d9a72c502ecfdda1b"
|
|
|
|
DEPENDS = "file-replacement-native"
|
|
DEPENDS_class-native = "bzip2-replacement-native"
|
|
|
|
SRC_URI = "git://github.com/file/file.git"
|
|
|
|
SRCREV = "ec41083645689a787cdd00cb3b5bf578aa79e46c"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools update-alternatives
|
|
|
|
PACKAGECONFIG ??= "zlib"
|
|
PACKAGECONFIG_class-native ??= "zlib"
|
|
PACKAGECONFIG[bz2] = "--enable-bzlib, --disable-bzlib, bzip2"
|
|
PACKAGECONFIG[lzma] = "--enable-xzlib, --disable-xzlib, xz"
|
|
PACKAGECONFIG[zlib] = "--enable-zlib, --disable-zlib, zlib"
|
|
|
|
EXTRA_OECONF += "--disable-libseccomp"
|
|
|
|
ALTERNATIVE_${PN} = "file"
|
|
ALTERNATIVE_LINK_NAME[file] = "${bindir}/file"
|
|
|
|
EXTRA_OEMAKE_append_class-target = " -e FILE_COMPILE=${STAGING_BINDIR_NATIVE}/file-native/file"
|
|
EXTRA_OEMAKE_append_class-nativesdk = " -e FILE_COMPILE=${STAGING_BINDIR_NATIVE}/file-native/file"
|
|
|
|
FILES_${PN} += "${datadir}/misc/*.mgc"
|
|
|
|
do_compile_append_class-native() {
|
|
oe_runmake check
|
|
}
|
|
|
|
do_install_append_class-native() {
|
|
create_cmdline_wrapper ${D}/${bindir}/file \
|
|
--magic-file ${datadir}/misc/magic.mgc
|
|
}
|
|
|
|
do_install_append_class-nativesdk() {
|
|
create_cmdline_wrapper ${D}/${bindir}/file \
|
|
--magic-file ${datadir}/misc/magic.mgc
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
PROVIDES_append_class-native = " file-replacement-native"
|
|
# Don't use NATIVE_PACKAGE_PATH_SUFFIX as that hides libmagic from anyone who
|
|
# depends on file-replacement-native.
|
|
bindir_append_class-native = "/file-native"
|