mirror of
https://git.yoctoproject.org/poky
synced 2026-02-26 19:39:40 +01:00
99956aa33a
The previous commit as below only fixes the
textrel issue with musl on x86, update it also to
fix the issue such as with glibc on x86.
74ea4f280c x264: Disable asm on musl/x86
[YOCTO #11770]
(From OE-Core rev: 521af79d1d7635b4bd0ee2cc45b96729285bf469)
Signed-off-by: Mingli Yu <mingli.yu@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
57 lines
1.8 KiB
BlitzBasic
57 lines
1.8 KiB
BlitzBasic
SUMMARY = "H.264/MPEG-4 AVC video encoder"
|
|
DESCRIPTION = "A free software library and application for encoding video streams into the H.264/MPEG-4 AVC format."
|
|
HOMEPAGE = "http://www.videolan.org/developers/x264.html"
|
|
|
|
LICENSE = "GPLv2"
|
|
LICENSE_FLAGS = "commercial"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
|
|
|
|
DEPENDS = "nasm-native"
|
|
|
|
SRC_URI = "git://github.com/mirror/x264;branch=stable \
|
|
file://don-t-default-to-cortex-a9-with-neon.patch \
|
|
file://Fix-X32-build-by-disabling-asm.patch \
|
|
"
|
|
UPSTREAM_CHECK_COMMITS = "1"
|
|
|
|
SRCREV = "e9a5903edf8ca59ef20e6f4894c196f135af735e"
|
|
|
|
PV = "r2854+git${SRCPV}"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit lib_package pkgconfig perlnative
|
|
|
|
X264_DISABLE_ASM = ""
|
|
X264_DISABLE_ASM_x86 = "--disable-asm"
|
|
X264_DISABLE_ASM_armv4 = "--disable-asm"
|
|
X264_DISABLE_ASM_armv5 = "--disable-asm"
|
|
X264_DISABLE_ASM_powerpc = "${@bb.utils.contains("TUNE_FEATURES", "spe", "--disable-asm", "", d)}"
|
|
X264_DISABLE_ASM_mipsarch = "${@bb.utils.contains("TUNE_FEATURES", "r6", "", "--disable-asm", d)}"
|
|
|
|
EXTRA_OECONF = '--prefix=${prefix} \
|
|
--host=${HOST_SYS} \
|
|
--libdir=${libdir} \
|
|
--cross-prefix=${TARGET_PREFIX} \
|
|
--sysroot=${STAGING_DIR_TARGET} \
|
|
--enable-shared \
|
|
--enable-static \
|
|
--disable-lavf \
|
|
--disable-swscale \
|
|
--disable-opencl \
|
|
--enable-pic \
|
|
${X264_DISABLE_ASM} \
|
|
'
|
|
|
|
do_configure() {
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}
|
|
./configure ${EXTRA_OECONF}
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR=${D}
|
|
}
|
|
|
|
AS[unexport] = "1"
|