mirror of
https://git.yoctoproject.org/poky
synced 2026-09-29 07:36:20 +02:00
f91604daee
This will allow to use the different DBDIR location, because the /var/lib could be used as a read-only location. (From OE-Core rev: 8fe5cff505f4fd942723d6f1526b0461747fc44d) Signed-off-by: Andrej Valek <andrej.valek@siemens.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
61 lines
2.0 KiB
BlitzBasic
61 lines
2.0 KiB
BlitzBasic
SECTION = "console/network"
|
|
SUMMARY = "dhcpcd - a DHCP client"
|
|
DESCRIPTION = "dhcpcd runs on your machine and silently configures your \
|
|
computer to work on the attached networks without trouble \
|
|
and mostly without configuration."
|
|
|
|
HOMEPAGE = "http://roy.marples.name/projects/dhcpcd/"
|
|
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=d148485768fe85b9f1072b186a7e9b4d"
|
|
|
|
UPSTREAM_CHECK_URI = "https://roy.marples.name/downloads/dhcpcd/"
|
|
|
|
SRC_URI = "https://roy.marples.name/downloads/${BPN}/${BPN}-${PV}.tar.xz \
|
|
file://0001-remove-INCLUDEDIR-to-prevent-build-issues.patch \
|
|
file://dhcpcd.service \
|
|
file://dhcpcd@.service \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "819357634efed1ea5cf44ec01b24d3d3f8852fec8b4249925dcc5667c54e376c"
|
|
|
|
inherit pkgconfig autotools-brokensep systemd useradd
|
|
|
|
SYSTEMD_SERVICE:${PN} = "dhcpcd.service"
|
|
|
|
PACKAGECONFIG ?= "udev ${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
|
|
|
|
PACKAGECONFIG[udev] = "--with-udev,--without-udev,udev,udev"
|
|
PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6"
|
|
# ntp conflicts with chrony
|
|
PACKAGECONFIG[ntp] = "--with-hook=ntp, , ,ntp"
|
|
PACKAGECONFIG[chrony] = "--with-hook=ntp, , ,chrony"
|
|
PACKAGECONFIG[ypbind] = "--with-eghook=yp, , ,ypbind-mt"
|
|
|
|
# add option to override DBDIR location
|
|
DBDIR ?= "${localstatedir}/lib/${BPN}"
|
|
|
|
EXTRA_OECONF = "--enable-ipv4 \
|
|
--dbdir=${DBDIR} \
|
|
--sbindir=${base_sbindir} \
|
|
--runstatedir=/run \
|
|
--enable-privsep \
|
|
--privsepuser=dhcpcd \
|
|
--with-hooks \
|
|
--with-eghooks \
|
|
"
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "--system -d ${DBDIR} -M -s /bin/false -U dhcpcd"
|
|
|
|
do_install:append () {
|
|
# install systemd unit files
|
|
install -d ${D}${systemd_system_unitdir}
|
|
install -m 0644 ${WORKDIR}/dhcpcd*.service ${D}${systemd_system_unitdir}
|
|
|
|
chmod 700 ${D}${DBDIR}
|
|
chown dhcpcd:dhcpcd ${D}${DBDIR}
|
|
}
|
|
|
|
FILES:${PN}-dbg += "${libdir}/dhcpcd/dev/.debug"
|