mirror of
https://git.yoctoproject.org/poky
synced 2026-05-02 18:32:15 +02:00
004e8062f1
Changelog: ========== - coretext: Implement reload_font - coretext: Use Menlo instead of Courier for monospace - win32: Avoid a double free - Update to Unicode 15.1 - Simplify hexbox drawing (From OE-Core rev: 1a2d7e127d251d0342044b9265e00c35357ead68) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
54 lines
1.9 KiB
BlitzBasic
54 lines
1.9 KiB
BlitzBasic
SUMMARY = "Framework for layout and rendering of internationalized text"
|
|
DESCRIPTION = "Pango is a library for laying out and rendering of text, \
|
|
with an emphasis on internationalization. Pango can be used anywhere \
|
|
that text layout is needed, though most of the work on Pango so far has \
|
|
been done in the context of the GTK+ widget toolkit. Pango forms the \
|
|
core of text and font handling for GTK+-2.x."
|
|
HOMEPAGE = "http://www.pango.org/"
|
|
BUGTRACKER = "http://bugzilla.gnome.org"
|
|
SECTION = "libs"
|
|
LICENSE = "LGPL-2.0-or-later"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7"
|
|
|
|
|
|
inherit gnomebase gi-docgen ptest-gnome upstream-version-is-even gobject-introspection
|
|
|
|
UPSTREAM_CHECK_REGEX = "pango-(?P<pver>\d+\.(?!9\d+)\d+\.\d+)"
|
|
|
|
GIR_MESON_ENABLE_FLAG = "enabled"
|
|
GIR_MESON_DISABLE_FLAG = "disabled"
|
|
|
|
SRC_URI += "file://run-ptest \
|
|
file://0001-Skip-running-test-layout-test.patch \
|
|
"
|
|
|
|
SRC_URI[archive.sha256sum] = "d0076afe01082814b853deec99f9349ece5f2ce83908b8e58ff736b41f78a96b"
|
|
|
|
DEPENDS = "glib-2.0 glib-2.0-native fontconfig freetype virtual/libiconv cairo harfbuzz fribidi"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)} \
|
|
${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)}"
|
|
|
|
PACKAGECONFIG[x11] = ",,virtual/libx11 libxft"
|
|
PACKAGECONFIG[tests] = "-Dinstall-tests=true, -Dinstall-tests=false"
|
|
PACKAGECONFIG[thai] = "-Dlibthai=enabled,-Dlibthai=disabled,libthai"
|
|
|
|
GIR_MESON_OPTION = 'introspection'
|
|
|
|
do_configure:prepend() {
|
|
chmod +x ${S}/tests/*.py
|
|
}
|
|
|
|
LEAD_SONAME = "libpango-1.0*"
|
|
|
|
FILES:${PN} = "${bindir}/* ${libdir}/libpango*${SOLIBS}"
|
|
|
|
RDEPENDS:${PN}-ptest += "cantarell-fonts"
|
|
RDEPENDS:${PN}-ptest:append:libc-glibc = " locale-base-en-us"
|
|
|
|
RPROVIDES:${PN} += "pango-modules pango-module-indic-lang \
|
|
pango-module-basic-fc pango-module-arabic-lang"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|