mirror of
https://git.yoctoproject.org/poky
synced 2026-09-20 12:49:33 +02:00
06fe8a9a4e
--{en|dis}able-gl-accel is spcefic to gl
patches in 0.15.1 which may not be available
for other qemu's so if someone chooses to remove
gl from PACKAGECONFIG then we dont explicitly
use the --disable-gl-accel option since this
wont be recognised by configure.
(From OE-Core rev: 68a170c9b69fc70b22167f344e6f72f028938066)
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
56 lines
1.8 KiB
PHP
56 lines
1.8 KiB
PHP
DESCRIPTION = "open source processor emulator"
|
|
HOMEPAGE = "http://qemu.org"
|
|
LICENSE = "GPLv2 & LGPLv2.1"
|
|
DEPENDS = "glib-2.0 zlib alsa-lib virtual/libx11"
|
|
|
|
# QEMU_TARGETS is overridable variable
|
|
QEMU_TARGETS ?= "arm i386 mips mipsel mips64 mips64el ppc sh4 x86_64"
|
|
|
|
require qemu-targets.inc
|
|
|
|
SDL ?= "--disable-sdl"
|
|
SDL_virtclass-native ?= ""
|
|
SDL_virtclass-nativesdk ?= ""
|
|
|
|
EXTRA_OECONF += "--target-list=${@get_qemu_target_list(d)} --disable-werror --disable-vnc-tls --audio-drv-list=oss,alsa --audio-card-list=ac97,es1370 ${SDL} --disable-curl --disable-vnc-jpeg"
|
|
|
|
#EXTRA_OECONF += "--disable-sdl"
|
|
|
|
|
|
inherit autotools
|
|
|
|
do_configure() {
|
|
# Handle distros such as CentOS 5 32-bit that do not have kvm support
|
|
KVMOPTS="--disable-kvm"
|
|
if [ "${PN}" != "qemu-native" ] || [ -f /usr/include/linux/kvm.h ] ; then
|
|
KVMOPTS="--enable-kvm"
|
|
fi
|
|
|
|
${S}/configure --prefix=${prefix} --sysconfdir=${sysconfdir} --disable-strip ${EXTRA_OECONF} $KVMOPTS
|
|
test ! -e ${S}/target-i386/beginend_funcs.sh || chmod a+x ${S}/target-i386/beginend_funcs.sh
|
|
}
|
|
|
|
do_install () {
|
|
export STRIP="true"
|
|
autotools_do_install
|
|
install -d ${D}${datadir}/qemu
|
|
install -m 0755 ${WORKDIR}/powerpc_rom.bin ${D}${datadir}/qemu
|
|
}
|
|
|
|
PACKAGECONFIG ??= "gl"
|
|
PACKAGECONFIG[gl] = "--enable-gl-accel,,,"
|
|
|
|
DEPENDS_virtclass-native = "zlib-native alsa-lib-native glib-2.0-native"
|
|
DEPENDS_virtclass-nativesdk = "zlib-nativesdk libsdl-nativesdk glib-2.0-nativesdk \
|
|
${@base_contains('DISTRO_FEATURES', 'x11', 'qemugl-nativesdk', '', d)}"
|
|
RDEPENDS_virtclass-nativesdk = "libsdl-nativesdk"
|
|
EXTRA_OECONF_virtclass-nativesdk += "--target-list=${@get_qemu_target_list(d)} --disable-werror --disable-vnc-tls"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# Qemu target will not build in world build for ARM or Mips
|
|
BROKEN_qemuarm = "1"
|
|
BROKEN_qemumips = "1"
|
|
|
|
INSANE_SKIP_${PN} = "arch"
|