mirror of
https://git.yoctoproject.org/poky
synced 2026-03-06 15:29:40 +01:00
120e9ca1be
Since wpa-supplicant is provided, the database of permitted frequencies should also be provided. wireless-regdb-static should be used with kernel >= 4.15. wireless-regdb can be used with older kernels and is mostly irrelevant here, but keeping it in meta-networking would create needless recipe duplication. This package was previously in meta-networking. (From OE-Core rev: 00c5a665b48c830a0008139b7ae1a51e79b72bb5) Signed-off-by: Adrian Bunk <bunk@stusta.de> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
45 lines
1.7 KiB
BlitzBasic
45 lines
1.7 KiB
BlitzBasic
SUMMARY = "Wireless Central Regulatory Domain Database"
|
|
HOMEPAGE = "http://wireless.kernel.org/en/developers/Regulatory/CRDA"
|
|
SECTION = "net"
|
|
LICENSE = "ISC"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=07c4f6dea3845b02a18dc00c8c87699c"
|
|
|
|
SRC_URI = "https://www.kernel.org/pub/software/network/${BPN}/${BP}.tar.xz"
|
|
SRC_URI[md5sum] = "4b5ba3f089db7fdb7b9daae6a7c1f2cb"
|
|
SRC_URI[sha256sum] = "cd917ed86b63ce8d93947979f1f18948f03a4ac0ad89ec25227b36ac00dc54bf"
|
|
|
|
inherit bin_package allarch
|
|
|
|
do_install() {
|
|
install -d -m0755 ${D}${nonarch_libdir}/crda
|
|
install -d -m0755 ${D}${sysconfdir}/wireless-regdb/pubkeys
|
|
install -m 0644 regulatory.bin ${D}${nonarch_libdir}/crda/regulatory.bin
|
|
install -m 0644 sforshee.key.pub.pem ${D}${sysconfdir}/wireless-regdb/pubkeys/sforshee.key.pub.pem
|
|
|
|
install -m 0644 -D regulatory.db ${D}${nonarch_base_libdir}/firmware/regulatory.db
|
|
install -m 0644 regulatory.db.p7s ${D}${nonarch_base_libdir}/firmware/regulatory.db.p7s
|
|
}
|
|
|
|
# Install static regulatory DB in /lib/firmware for kernel to load.
|
|
# This requires Linux kernel >= v4.15.
|
|
# For kernel <= v4.14, inherit the kernel_wireless_regdb.bbclass
|
|
# (in meta-networking) in kernel's recipe.
|
|
PACKAGES = "${PN}-static ${PN}"
|
|
RCONFLICTS_${PN} = "${PN}-static"
|
|
|
|
FILES_${PN}-static = " \
|
|
${nonarch_base_libdir}/firmware/regulatory.db \
|
|
${nonarch_base_libdir}/firmware/regulatory.db.p7s \
|
|
"
|
|
|
|
# Native users might want to use the source of regulatory DB.
|
|
# This is for example used by Linux kernel <= v4.14 and
|
|
# kernel_wireless_regdb.bbclass in meta-networking.
|
|
do_install_append_class-native() {
|
|
install -m 0644 -D db.txt ${D}${libdir}/crda/db.txt
|
|
}
|
|
|
|
RSUGGESTS_${PN} = "crda"
|
|
|
|
BBCLASSEXTEND = "native"
|