mirror of
https://git.yoctoproject.org/poky
synced 2026-02-20 08:29:42 +01:00
aef302222a
License-update: switch to a dedicated license file; the license terms are the same. (From OE-Core rev: b505414862f80bc835ebba005a76c4428a657478) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Luca Ceresoli <luca.ceresoli@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
49 lines
1.3 KiB
BlitzBasic
49 lines
1.3 KiB
BlitzBasic
SUMMARY = "LiSt Open Files tool"
|
|
DESCRIPTION = "Lsof is a Unix-specific diagnostic tool. \
|
|
Its name stands for LiSt Open Files, and it does just that."
|
|
HOMEPAGE = "http://people.freebsd.org/~abe/"
|
|
SECTION = "devel"
|
|
LICENSE = "Spencer-94"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=a48ac97a8550eff12395a2c0d6151510"
|
|
|
|
SRC_URI = "git://github.com/lsof-org/lsof;branch=master;protocol=https \
|
|
file://remove-host-information.patch"
|
|
SRCREV = "546eb1c9910e7c137fdff551683c35a736021e05"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE:${PN} = "lsof"
|
|
ALTERNATIVE_LINK_NAME[lsof] = "${sbindir}/lsof"
|
|
# Make our priority higher than busybox
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
|
|
export LSOF_INCLUDE = "${STAGING_INCDIR}"
|
|
|
|
do_configure () {
|
|
export LSOF_AR="${AR} cr"
|
|
export LSOF_RANLIB="${RANLIB}"
|
|
if [ "x${GLIBCVERSION}" != "x" ]; then
|
|
LINUX_CLIB=`echo ${GLIBCVERSION} |sed -e 's,\.,,g'`
|
|
LINUX_CLIB="-DGLIBCV=${LINUX_CLIB}"
|
|
export LINUX_CLIB
|
|
fi
|
|
yes | ./Configure linux
|
|
}
|
|
|
|
export I = "${STAGING_INCDIR}"
|
|
export L = "${STAGING_INCDIR}"
|
|
|
|
do_compile () {
|
|
oe_runmake 'CC=${CC}' 'CFGL=${LDFLAGS} -L./lib -llsof' 'DEBUG=' 'INCL=${CFLAGS} -I..'
|
|
}
|
|
|
|
do_install () {
|
|
install -d ${D}${sbindir} ${D}${mandir}/man8
|
|
install -m 0755 lsof ${D}${sbindir}/lsof
|
|
install -m 0644 Lsof.8 ${D}${mandir}/man8/lsof.8
|
|
}
|