mirror of
https://git.yoctoproject.org/poky
synced 2026-02-22 01:19:41 +01:00
46834de410
(From OE-Core rev: 4113f9f23a231cdb7cf9072c05ff743c63fdbdac) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
49 lines
1.3 KiB
BlitzBasic
49 lines
1.3 KiB
BlitzBasic
SUMMARY = "LiSt Open Files tool"
|
|
DESCRIPTION = "Lsof is a Unix-specific diagnostic tool. \
|
|
Its name stands for LiSt Open Files, and it does just that."
|
|
HOMEPAGE = "http://people.freebsd.org/~abe/"
|
|
SECTION = "devel"
|
|
LICENSE = "Spencer-94"
|
|
LIC_FILES_CHKSUM = "file://00README;beginline=645;endline=679;md5=964df275d26429ba3b39dbb9f205172a"
|
|
|
|
SRC_URI = "git://github.com/lsof-org/lsof;branch=master;protocol=https \
|
|
file://remove-host-information.patch"
|
|
SRCREV = "898916d4c7c390ea4610aebaf1d32b8a3c49f26b"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE_${PN} = "lsof"
|
|
ALTERNATIVE_LINK_NAME[lsof] = "${sbindir}/lsof"
|
|
# Make our priority higher than busybox
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
|
|
export LSOF_INCLUDE = "${STAGING_INCDIR}"
|
|
|
|
do_configure () {
|
|
export LSOF_AR="${AR} cr"
|
|
export LSOF_RANLIB="${RANLIB}"
|
|
if [ "x${GLIBCVERSION}" != "x" ]; then
|
|
LINUX_CLIB=`echo ${GLIBCVERSION} |sed -e 's,\.,,g'`
|
|
LINUX_CLIB="-DGLIBCV=${LINUX_CLIB}"
|
|
export LINUX_CLIB
|
|
fi
|
|
yes | ./Configure linux
|
|
}
|
|
|
|
export I = "${STAGING_INCDIR}"
|
|
export L = "${STAGING_INCDIR}"
|
|
|
|
do_compile () {
|
|
oe_runmake 'CC=${CC}' 'CFGL=${LDFLAGS} -L./lib -llsof' 'DEBUG=' 'INCL=${CFLAGS}'
|
|
}
|
|
|
|
do_install () {
|
|
install -d ${D}${sbindir} ${D}${mandir}/man8
|
|
install -m 0755 lsof ${D}${sbindir}/lsof
|
|
install -m 0644 Lsof.8 ${D}${mandir}/man8/lsof.8
|
|
}
|