mirror of
https://git.yoctoproject.org/poky
synced 2026-03-04 06:19:40 +01:00
b728951085
In the recent upgrade, which started to be installed as which.debianutils and the man page was also renamed. Update the recipe to remove the now unneeded man page alternatives and rename the binary to match what the code expects. This avoids warnings like: WARNING: debianutils-5.14-r0 do_package: debianutils: alternative target (/usr/share/man/man1/which.1 or /usr/share/man/man1/which.1.debianutils) does not exist, skipping... WARNING: debianutils-5.14-r0 do_package: debianutils: NOT adding alternative provide /usr/share/man/man1/which.1: /usr/share/man/man1/which.1.debianutils does not exist WARNING: debianutils-5.14-r0 do_package: debianutils: alt_link == alt_target: /usr/share/man/man1/which.1 == /usr/share/man/man1/which.1 (From OE-Core rev: 9f8d3438530abceabdfd03d2ff2157bb79e4e034) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
59 lines
2.0 KiB
BlitzBasic
59 lines
2.0 KiB
BlitzBasic
SUMMARY = "Miscellaneous utilities specific to Debian"
|
|
DESCRIPTION = "Provides a number of small utilities which are used \
|
|
primarily by the installation scripts of Debian packages, although \
|
|
you may use them directly. "
|
|
HOMEPAGE = "https://packages.debian.org/sid/debianutils"
|
|
BUGTRACKER = "https://bugs.debian.org/cgi-bin/pkgreport.cgi?pkg=debianutils;dist=unstable"
|
|
SECTION = "base"
|
|
LICENSE = "GPL-2.0-only & SMAIL_GPL"
|
|
LIC_FILES_CHKSUM = "file://debian/copyright;md5=4b667f30411d21bc8fd7db85d502a8e9"
|
|
|
|
SRC_URI = "git://salsa.debian.org/debian/debianutils.git;protocol=https;branch=master \
|
|
"
|
|
|
|
SRCREV = "7e63b32ea4126c70a5da958f0106add267810a94"
|
|
|
|
inherit autotools update-alternatives
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# Disable po4a (translated manpages) sub-directory, as that requires po4a to build
|
|
do_configure:prepend() {
|
|
sed -i -e 's:po4a::g' ${S}/Makefile.am
|
|
}
|
|
|
|
|
|
do_install:append() {
|
|
if [ "${base_bindir}" != "${bindir}" ]; then
|
|
# Debian places some utils into ${base_bindir} as does busybox
|
|
install -d ${D}${base_bindir}
|
|
for app in run-parts; do
|
|
mv ${D}${bindir}/$app ${D}${base_bindir}/$app
|
|
done
|
|
fi
|
|
mv ${D}${bindir}/which.debianutils ${D}${bindir}/which
|
|
}
|
|
|
|
# Note that we package the update-alternatives name.
|
|
#
|
|
PACKAGES =+ "${PN}-run-parts"
|
|
FILES:${PN}-run-parts = "${base_bindir}/run-parts.debianutils"
|
|
|
|
RDEPENDS:${PN} += "${PN}-run-parts"
|
|
RDEPENDS:${PN}:class-native = ""
|
|
|
|
ALTERNATIVE_PRIORITY = "30"
|
|
ALTERNATIVE:${PN} = "add-shell installkernel remove-shell savelog which"
|
|
|
|
ALTERNATIVE_PRIORITY_${PN}-run-parts = "60"
|
|
ALTERNATIVE:${PN}-run-parts = "run-parts"
|
|
|
|
ALTERNATIVE_LINK_NAME[add-shell] = "${sbindir}/add-shell"
|
|
ALTERNATIVE_LINK_NAME[installkernel] = "${sbindir}/installkernel"
|
|
ALTERNATIVE_LINK_NAME[remove-shell] = "${sbindir}/remove-shell"
|
|
ALTERNATIVE_LINK_NAME[run-parts] = "${base_bindir}/run-parts"
|
|
ALTERNATIVE_LINK_NAME[savelog] = "${bindir}/savelog"
|
|
ALTERNATIVE_LINK_NAME[which] = "${bindir}/which"
|
|
|
|
BBCLASSEXTEND = "native"
|