mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 00:32:12 +02:00
4274ee5c14
As libdrm enables modules automatically, based on what it needs / can build, it's unlikely we'll *ever* get a situation where all the modules are emitted, so libdrm-drivers, which depends on all of them, ends up being useless and non-installable. Make it use rrecommends, so it only pulls in what we have. (From OE-Core rev: faa5fc8c4d6cf236cd87d3308a2828d37da97742) Signed-off-by: Christopher Larson <kergoth@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
40 lines
1.6 KiB
PHP
40 lines
1.6 KiB
PHP
SUMMARY = "Userspace interface to the kernel DRM services"
|
|
DESCRIPTION = "The runtime library for accessing the kernel DRM services. DRM \
|
|
stands for \"Direct Rendering Manager\", which is the kernel portion of the \
|
|
\"Direct Rendering Infrastructure\" (DRI). DRI is required for many hardware \
|
|
accelerated OpenGL drivers."
|
|
HOMEPAGE = "http://dri.freedesktop.org"
|
|
SECTION = "x11/base"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://xf86drm.c;beginline=9;endline=32;md5=c8a3b961af7667c530816761e949dc71"
|
|
SRC_URI = "http://dri.freedesktop.org/libdrm/libdrm-${PV}.tar.bz2"
|
|
PROVIDES = "drm"
|
|
DEPENDS = "libpthread-stubs udev"
|
|
|
|
# be aware that libdrm_2.4.44.bb ignores this
|
|
INC_PR = "r4"
|
|
|
|
#libpciaccess is required starting from libdrm 2.4.26
|
|
DEPENDS += " libpciaccess"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
EXTRA_OECONF += "--disable-cairo-tests \
|
|
--enable-omap-experimental-api \
|
|
--enable-install-test-programs \
|
|
"
|
|
ALLOW_EMPTY_${PN}-drivers = "1"
|
|
PACKAGES =+ "${PN}-tests ${PN}-drivers ${PN}-radeon ${PN}-nouveau ${PN}-omap \
|
|
${PN}-intel ${PN}-exynos ${PN}-kms"
|
|
|
|
RRECOMMENDS_${PN}-drivers = "${PN}-radeon ${PN}-nouveau ${PN}-omap ${PN}-intel \
|
|
${PN}-exynos"
|
|
|
|
FILES_${PN}-tests = "${bindir}/dr* ${bindir}/mode* ${bindir}/*test"
|
|
FILES_${PN}-radeon = "${libdir}/libdrm_radeon.so.*"
|
|
FILES_${PN}-nouveau = "${libdir}/libdrm_nouveau.so.*"
|
|
FILES_${PN}-omap = "${libdir}/libdrm_omap.so.*"
|
|
FILES_${PN}-intel = "${libdir}/libdrm_intel.so.*"
|
|
FILES_${PN}-exynos = "${libdir}/libdrm_exynos.so.*"
|
|
FILES_${PN}-kms = "${libdir}/libkms*.so.*"
|