mirror of
https://git.yoctoproject.org/poky
synced 2026-04-27 12:32:13 +02:00
db827dd6ec
The result of getfacl is sorted by user id. In Centos or RHEL, bin user id is 1 and daemon user id is 2. But in our image, bin user id is 2 and daemon user id is 1. The patch fixes this issue to make ptest pass. (From OE-Core rev: a5180e942c9315d280580773e72fe67f27629a3c) Signed-off-by: Chong Lu <Chong.Lu@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
40 lines
1.2 KiB
PHP
40 lines
1.2 KiB
PHP
SUMMARY = "Utilities for managing POSIX Access Control Lists"
|
|
HOMEPAGE = "http://savannah.nongnu.org/projects/acl/"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "LGPLv2.1+ & GPLv2+"
|
|
LICENSE_${PN} = "GPLv2+"
|
|
LICENSE_lib${BPN} = "LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://doc/COPYING;md5=c781d70ed2b4d48995b790403217a249 \
|
|
file://doc/COPYING.LGPL;md5=9e9a206917f8af112da634ce3ab41764"
|
|
|
|
DEPENDS = "attr"
|
|
SRC_URI = "http://download.savannah.gnu.org/releases/acl/${BP}.src.tar.gz \
|
|
file://run-ptest \
|
|
file://acl-fix-the-order-of-expected-output-of-getfacl.patch \
|
|
"
|
|
|
|
require ea-acl.inc
|
|
|
|
# avoid RPATH hardcode to staging dir
|
|
do_configure_append() {
|
|
sed -i ${S}/config.status -e s,^\\\(hardcode_into_libs=\\\).*$,\\1\'no\',
|
|
${S}/config.status
|
|
}
|
|
|
|
# libdir should point to .la
|
|
do_install_append() {
|
|
sed -i ${D}${libdir}/libacl.la -e \
|
|
s,^libdir=\'${base_libdir}\'$,libdir=\'${libdir}\',
|
|
}
|
|
|
|
inherit ptest
|
|
|
|
do_install_ptest() {
|
|
tar -cf - test/ --exclude nfs | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
mkdir ${D}${PTEST_PATH}/include
|
|
cp ${S}/include/builddefs ${S}/include/buildmacros ${S}/include/buildrules ${D}${PTEST_PATH}/include/
|
|
}
|
|
|
|
RDEPENDS_${PN}-ptest = "bash coreutils perl perl-module-filehandle perl-module-getopt-std perl-module-posix shadow"
|