mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 16:28:43 +01:00
b5adb300dd
This patch fixes compilation/linking of python third-party extensions, i.e. Extensions that ship with C code. Problem: Python uses distutils(-native) to compile third-party extensions. distutils uses its own sysconfig module to get the options for compiling and linking. Since third-party extensions have to be linked against this libpython it important that -L points into staging. This is not the case because distutils.sysconfig uses a special Makefile that is shipped with python determine the paths. The Makefile is the same that would be used on the target to build third-party extensions. It therefore points into /usr/lib instead of staging. Solution: Stage a modified version of the Makefile where the paths (incdir, libdir) have been replaced by ones that point into staging. Side-problem: The recipe actually should not stage files itself in do_compile, but rather handle everything that needs to be staged in do_install. This is currently not possible because python compiles itself using distutils-native. Distutils on the other hand does only allow to add a path, but not to substitute it, requiring a staged Makefile and libpython.so before the actual python compilation is triggered. The second step to solve this would be to either patch distutils, or split python into python-initial and python. The -initial part could create the Makefile and the library, while the main part focuses on the target. For further references see: http://lists.linuxtogo.org/pipermail/openembedded-core/2011-May/001752.html (From OE-Core rev: 413e7e5a5d6db45a6fbca5044246d6696d9d5711) Signed-off-by: Michael Lippautz <michael.lippautz@gmail.com> Acked-by: Martin Jansa <Martin.Jansa@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
145 lines
4.7 KiB
BlitzBasic
145 lines
4.7 KiB
BlitzBasic
require python.inc
|
|
DEPENDS = "python-native db gdbm openssl readline sqlite3 zlib"
|
|
DEPENDS_sharprom = "python-native db readline zlib gdbm openssl"
|
|
PR = "${INC_PR}.3"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=38fdd546420fab09ac6bd3d8a1c83eb6"
|
|
|
|
DISTRO_SRC_URI ?= "file://sitecustomize.py"
|
|
DISTRO_SRC_URI_linuxstdbase = ""
|
|
SRC_URI = "\
|
|
http://www.python.org/ftp/python/${PV}/Python-${PV}.tar.bz2 \
|
|
file://01-use-proper-tools-for-cross-build.patch \
|
|
file://02-remove-test-for-cross.patch \
|
|
file://03-fix-tkinter-detection.patch \
|
|
file://04-default-is-optimized.patch \
|
|
file://05-enable-ctypes-cross-build.patch \
|
|
file://06-ctypes-libffi-fix-configure.patch \
|
|
file://06-avoid_usr_lib_termcap_path_in_linking.patch \
|
|
file://99-ignore-optimization-flag.patch \
|
|
${DISTRO_SRC_URI} \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "cf4e6881bb84a7ce6089e4a307f71f14"
|
|
SRC_URI[sha256sum] = "134c5e0736bae2e5570d0b915693374f11108ded63c35a23a35d282737d2ce83"
|
|
S = "${WORKDIR}/Python-${PV}"
|
|
|
|
inherit autotools
|
|
|
|
# The 3 lines below are copied from the libffi recipe, ctypes ships its own copy of the libffi sources
|
|
#Somehow gcc doesn't set __SOFTFP__ when passing -mfloatabi=softp :(
|
|
TARGET_CC_ARCH_append_armv6 = " -D__SOFTFP__"
|
|
TARGET_CC_ARCH_append_armv7a = " -D__SOFTFP__"
|
|
|
|
do_configure_prepend() {
|
|
autoreconf -Wcross --verbose --install --force --exclude=autopoint Modules/_ctypes/libffi || bbnote "_ctypes failed to autoreconf"
|
|
}
|
|
|
|
do_compile() {
|
|
#
|
|
# Copy config.h and an appropriate Makefile for distutils.sysconfig,
|
|
# which laters uses the information out of these to compile extensions
|
|
#
|
|
# The following part (until python compilation) should probably moved to an
|
|
# -initial recipe to handle staging better
|
|
#
|
|
install -d ${STAGING_INCDIR}/python${PYTHON_MAJMIN}/
|
|
install -d ${STAGING_LIBDIR}/python${PYTHON_MAJMIN}/config/
|
|
install -m 0644 pyconfig.h ${STAGING_INCDIR}/python${PYTHON_MAJMIN}/
|
|
|
|
# remove hardcoded ccache, see http://bugs.openembedded.net/show_bug.cgi?id=4144
|
|
sed -i -e s,ccache,'$(CCACHE)', Makefile
|
|
|
|
install -m 0644 Makefile Makefile.orig
|
|
sed -i -e 's,${includedir},${STAGING_INCDIR},' Makefile
|
|
sed -i -e 's,${libdir},${STAGING_LIBDIR},' Makefile
|
|
install -m 0644 Makefile ${STAGING_LIBDIR}/python${PYTHON_MAJMIN}/config/
|
|
|
|
oe_runmake HOSTPGEN=${STAGING_BINDIR_NATIVE}/pgen \
|
|
HOSTPYTHON=${STAGING_BINDIR_NATIVE}/python \
|
|
STAGING_LIBDIR=${STAGING_LIBDIR} \
|
|
STAGING_INCDIR=${STAGING_INCDIR} \
|
|
BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
|
|
OPT="${CFLAGS}" libpython${PYTHON_MAJMIN}.so
|
|
|
|
oe_libinstall -so libpython${PYTHON_MAJMIN} ${STAGING_LIBDIR}
|
|
|
|
oe_runmake HOSTPGEN=${STAGING_BINDIR_NATIVE}/pgen \
|
|
HOSTPYTHON=${STAGING_BINDIR_NATIVE}/python \
|
|
STAGING_LIBDIR=${STAGING_LIBDIR} \
|
|
STAGING_INCDIR=${STAGING_INCDIR} \
|
|
BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
|
|
OPT="${CFLAGS}"
|
|
}
|
|
|
|
do_install() {
|
|
# make install needs the original Makefile, or otherwise the inclues would
|
|
# go to ${D}${STAGING...}/...
|
|
install -m 0644 Makefile Makefile.sysroot
|
|
install -m 0644 Makefile.orig Makefile
|
|
|
|
oe_runmake HOSTPGEN=${STAGING_BINDIR_NATIVE}/pgen \
|
|
HOSTPYTHON=${STAGING_BINDIR_NATIVE}/python \
|
|
STAGING_LIBDIR=${STAGING_LIBDIR} \
|
|
STAGING_INCDIR=${STAGING_INCDIR} \
|
|
BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
|
|
DESTDIR=${D} LIBDIR=${libdir} install
|
|
|
|
install -m 0644 Makefile.sysroot ${D}/${libdir}/python${PYTHON_MAJMIN}/config/Makefile
|
|
rm Makefile.sysroot
|
|
|
|
if [ -e ${WORKDIR}/sitecustomize.py ]; then
|
|
install -m 0644 ${WORKDIR}/sitecustomize.py ${D}/${libdir}/python${PYTHON_MAJMIN}
|
|
fi
|
|
}
|
|
|
|
PACKAGE_PREPROCESS_FUNCS += "py_package_preprocess"
|
|
|
|
py_package_preprocess () {
|
|
# copy back the old Makefile to fix target package
|
|
install -m 0644 Makefile.orig ${D}/${libdir}/python${PYTHON_MAJMIN}/config/Makefile
|
|
}
|
|
|
|
require python-${PYTHON_MAJMIN}-manifest.inc
|
|
|
|
# manual dependency additions
|
|
RPROVIDES_${PN}-core = "${PN}"
|
|
RRECOMMENDS_${PN}-core = "${PN}-readline"
|
|
RRECOMMENDS_${PN}-crypt = "openssl"
|
|
|
|
# add sitecustomize
|
|
FILES_${PN}-core += "${libdir}/python${PYTHON_MAJMIN}/sitecustomize.py"
|
|
# ship 2to3
|
|
FILES_${PN}-core += "${bindir}/2to3"
|
|
|
|
# package libpython2
|
|
PACKAGES =+ "lib${PN}2"
|
|
FILES_lib${PN}2 = "${libdir}/libpython*.so*"
|
|
|
|
# additional stuff -dev
|
|
|
|
FILES_${PN}-dev = "\
|
|
${includedir} \
|
|
${libdir}/lib*${SOLIBSDEV} \
|
|
${libdir}/*.la \
|
|
${libdir}/*.a \
|
|
${libdir}/*.o \
|
|
${libdir}/pkgconfig \
|
|
${base_libdir}/*.a \
|
|
${base_libdir}/*.o \
|
|
${datadir}/aclocal \
|
|
${datadir}/pkgconfig \
|
|
"
|
|
|
|
# catch debug extensions (isn't that already in python-core-dbg?)
|
|
FILES_${PN}-dbg += "${libdir}/python${PYTHON_MAJMIN}/lib-dynload/.debug"
|
|
|
|
# catch all the rest (unsorted)
|
|
PACKAGES += "${PN}-misc"
|
|
FILES_${PN}-misc = "${libdir}/python${PYTHON_MAJMIN}"
|
|
|
|
# catch manpage
|
|
PACKAGES += "${PN}-man"
|
|
FILES_${PN}-man = "${datadir}/man"
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|