mirror of
https://git.yoctoproject.org/poky
synced 2026-05-05 07:39:49 +02:00
c8dee9b92d
This is the result of running the following over the metadata: sed \ -e 's:bb.data.\(setVar([^,()]*,[^,()]*\), *\([^ )]*\) *):\2.\1):g' \ -e 's:bb.data.\(setVarFlag([^,()]*,[^,()]*,[^,()]*\), *\([^) ]*\) *):\2.\1):g' \ -e 's:bb.data.\(getVar([^,()]*\), *\([^(), ]*\) *,\([^)]*\)):\2.\1,\3):g' \ -e 's:bb.data.\(getVarFlag([^,()]*,[^,()]*\), *\([^(), ]*\) *,\([^)]*\)):\2.\1,\3):g' \ -e 's:bb.data.\(getVarFlag([^,()]*,[^,()]*\), *\([^() ]*\) *):\2.\1):g' \ -e 's:bb.data.\(getVar([^,()]*\), *\([^) ]*\) *):\2.\1):g' \ -i `grep -ril bb.data *` (From OE-Core rev: b22831fd63164c4db9c0b72934d7d734a6585251) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
52 lines
1.7 KiB
PHP
52 lines
1.7 KiB
PHP
SUMMARY = "Framework for layout and rendering of internationalized text"
|
|
DESCRIPTION = "Pango is a library for laying out and rendering of text, \
|
|
with an emphasis on internationalization. Pango can be used anywhere \
|
|
that text layout is needed, though most of the work on Pango so far has \
|
|
been done in the context of the GTK+ widget toolkit. Pango forms the \
|
|
core of text and font handling for GTK+-2.x."
|
|
HOMEPAGE = "http://www.pango.org/"
|
|
BUGTRACKER = "http://bugzilla.gnome.org"
|
|
SECTION = "libs"
|
|
LICENSE = "LGPL"
|
|
|
|
X11DEPENDS = "virtual/libx11 libxft"
|
|
DEPENDS = "glib-2.0 fontconfig freetype zlib virtual/libiconv gtk-doc-native cairo ${@base_contains('DISTRO_FEATURES', 'x11', '${X11DEPENDS}', '', d)}"
|
|
|
|
PACKAGES_DYNAMIC = "pango-module-*"
|
|
|
|
RRECOMMENDS_${PN} = "${@base_contains('DISTRO_FEATURES', 'x11', 'pango-module-basic-x', '', d)} pango-module-basic-fc"
|
|
|
|
inherit gnome
|
|
|
|
EXTRA_AUTORECONF = ""
|
|
|
|
# seems to go wrong with default cflags
|
|
FULL_OPTIMIZATION_arm = "-O2"
|
|
|
|
EXTRA_OECONF = "--disable-glibtest \
|
|
--enable-explicit-deps=no \
|
|
--disable-debug \
|
|
${@base_contains('DISTRO_FEATURES', 'x11', '--with-x', '--without-x', d)}"
|
|
|
|
LEAD_SONAME = "libpango-1.0*"
|
|
LIBV = "1.6.0"
|
|
|
|
postinst_prologue() {
|
|
if [ "x$D" != "x" ]; then
|
|
exit 1
|
|
fi
|
|
|
|
}
|
|
|
|
python populate_packages_prepend () {
|
|
prologue = d.getVar("postinst_prologue", 1)
|
|
|
|
modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
|
|
|
|
do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', prologue + 'pango-querymodules > /etc/pango/pango.modules')
|
|
}
|
|
|
|
FILES_${PN} = "/etc ${bindir}/* ${libdir}/libpango*${SOLIBS}"
|
|
FILES_${PN}-dbg += "${libdir}/pango/${LIBV}/modules/.debug"
|
|
FILES_${PN}-dev += "${libdir}/pango/${LIBV}/modules/*.la"
|