mirror of
https://git.yoctoproject.org/poky
synced 2026-02-25 10:59:41 +01:00
fb838e297e
go1.19.4 (released 2022-12-06) includes security fixes to the net/http and os packages, as well as bug fixes to the compiler, the runtime, and the crypto/x509, os/exec, and sync/atomic packages. (From OE-Core rev: e07f253e14a3651dd4e3d0e4d75c546f40bea8c1) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 67301425ac2696ccc07d6f47856336d6336382fb) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
48 lines
1.3 KiB
BlitzBasic
48 lines
1.3 KiB
BlitzBasic
# This recipe is for bootstrapping our go-cross from a prebuilt binary of Go from golang.org.
|
|
|
|
SUMMARY = "Go programming language compiler (upstream binary for bootstrap)"
|
|
HOMEPAGE = " http://golang.org/"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=5d4950ecb7b26d2c5e4e7b4e0dd74707"
|
|
|
|
PROVIDES = "go-native"
|
|
|
|
# Checksums available at https://go.dev/dl/
|
|
SRC_URI = "https://dl.google.com/go/go${PV}.${BUILD_GOOS}-${BUILD_GOARCH}.tar.gz;name=go_${BUILD_GOTUPLE}"
|
|
SRC_URI[go_linux_amd64.sha256sum] = "c9c08f783325c4cf840a94333159cc937f05f75d36a8b307951d5bd959cf2ab8"
|
|
SRC_URI[go_linux_arm64.sha256sum] = "9df122d6baf6f2275270306b92af3b09d7973fb1259257e284dba33c0db14f1b"
|
|
|
|
UPSTREAM_CHECK_URI = "https://golang.org/dl/"
|
|
UPSTREAM_CHECK_REGEX = "go(?P<pver>\d+(\.\d+)+)\.linux"
|
|
|
|
S = "${WORKDIR}/go"
|
|
|
|
inherit goarch native
|
|
|
|
do_compile() {
|
|
:
|
|
}
|
|
|
|
make_wrapper() {
|
|
rm -f ${D}${bindir}/$1
|
|
cat <<END >${D}${bindir}/$1
|
|
#!/bin/bash
|
|
here=\`dirname \$0\`
|
|
export GOROOT="${GOROOT:-\`readlink -f \$here/../lib/go\`}"
|
|
\$here/../lib/go/bin/$1 "\$@"
|
|
END
|
|
chmod +x ${D}${bindir}/$1
|
|
}
|
|
|
|
do_install() {
|
|
find ${S} -depth -type d -name testdata -exec rm -rf {} +
|
|
|
|
install -d ${D}${bindir} ${D}${libdir}/go
|
|
cp --preserve=mode,timestamps -R ${S}/ ${D}${libdir}/
|
|
|
|
for f in ${S}/bin/*
|
|
do
|
|
make_wrapper `basename $f`
|
|
done
|
|
}
|