mirror of
https://git.yoctoproject.org/poky
synced 2026-02-21 17:09:42 +01:00
ec1ae11f78
The don't show up in CVE metrics anymore since they were either fixed upstream or recipe version was upgraded meanwhile. * bind CVE-2019-6470: cpe got corrected in nvd db * libxml2 CVE-2023-45322: version is now higher than NVD cpe * zlib CVE-2023-45853: version is now higher than NVD cpe * gcc CVE-2021-37322: version is now higher than NVD cpe * python3 * CVE-2007-4559: version is now higher than NVD cpe * CVE-2019-18348: version is now higher than NVD cpe * CVE-2020-15523: version is now higher than NVD cpe * CVE-2022-26488: version is now higher than NVD cpe * CVE-2015-20107: version is now higher than NVD cpe * CVE-2023-36632: version is now higher than NVD cpe * rust * CVE-2024-24576: NVD has no cpe, but we have newer version as fix * CVE-2024-43402: version is now higher than NVD cpe * cups CVE-2021-25317: version is now higher than NVD cpe * ghostscript CVE-2023-38559: version is now higher than NVD cpe * libtirpc CVE-2021-46828: version is now higher than NVD cpe * unzip CVE-2008-0888: version is now higher than NVD cpe * ffmpeg CVE-2023-39018: cpe got corrected in nvd db * libxslt CVE-2022-29824: version is now higher than NVD cpe * libyaml * CVE-2024-35325: CVE is now rejected in NVD DB * CVE-2024-35326: CVE is now rejected in NVD DB * CVE-2024-35328: CVE is now rejected in NVD DB Also add comment for iputils regarding reports for FKIE/NVD2. Also remove some trailing spaces in python recipe. (From OE-Core rev: 73ee9789183aa95072af2b51ac9e08203f4e33f9) Signed-off-by: Peter Marko <peter.marko@siemens.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
77 lines
3.0 KiB
BlitzBasic
77 lines
3.0 KiB
BlitzBasic
SUMMARY = "The GPL Ghostscript PostScript/PDF interpreter"
|
|
DESCRIPTION = "Ghostscript is used for PostScript/PDF preview and printing. Usually as \
|
|
a back-end to a program such as ghostview, it can display PostScript and PDF \
|
|
documents in an X11 environment. \
|
|
\
|
|
Furthermore, it can render PostScript and PDF files as graphics to be printed \
|
|
on non-PostScript printers. Supported printers include common \
|
|
dot-matrix, inkjet and laser models. \
|
|
"
|
|
HOMEPAGE = "http://www.ghostscript.com"
|
|
SECTION = "console/utils"
|
|
|
|
LICENSE = "AGPL-3.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=f98ffa763e50cded76f49bce73aade16"
|
|
|
|
DEPENDS = "tiff jpeg fontconfig cups libpng freetype zlib"
|
|
|
|
UPSTREAM_CHECK_URI = "https://github.com/ArtifexSoftware/ghostpdl-downloads/releases"
|
|
UPSTREAM_CHECK_REGEX = "(?P<pver>\d+(\.\d+)+)\.tar"
|
|
|
|
def gs_verdir(v):
|
|
return "".join(v.split("."))
|
|
|
|
SRC_URI = "https://github.com/ArtifexSoftware/ghostpdl-downloads/releases/download/gs${@gs_verdir("${PV}")}/${BPN}-${PV}.tar.gz \
|
|
file://ghostscript-9.16-Werror-return-type.patch \
|
|
file://avoid-host-contamination.patch \
|
|
file://0001-Bug-708160-Fix-compatibility-with-C23-compilers.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "121861b6d29b2461dec6575c9f3cab665b810bd408d4ec02c86719fa708b0a49"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[gtk] = "--enable-gtk,--disable-gtk,gtk+3"
|
|
PACKAGECONFIG[libidn] = "--with-libidn,--without-libidn,libidn"
|
|
PACKAGECONFIG[libpaper] = "--with-libpaper,--without-libpaper,libpaper"
|
|
PACKAGECONFIG[x11] = "--with-x --x-includes=${STAGING_INCDIR} --x-libraries=${STAGING_LIBDIR}, \
|
|
--without-x, virtual/libx11 libxext libxt"
|
|
|
|
EXTRA_OECONF = "--with-jbig2dec \
|
|
--with-fontpath=${datadir}/fonts \
|
|
CUPSCONFIG="${STAGING_BINDIR_CROSS}/cups-config" \
|
|
PKGCONFIG=pkg-config \
|
|
"
|
|
|
|
EXTRA_OECONF:append:mipsarcho32 = " --with-large_color_index=0"
|
|
|
|
EXTRA_OECONF:append:armv7a = "${@bb.utils.contains('TUNE_FEATURES','neon','',' --disable-neon',d)}"
|
|
EXTRA_OECONF:append:armv7ve = "${@bb.utils.contains('TUNE_FEATURES','neon','',' --disable-neon',d)}"
|
|
|
|
TARGET_CFLAGS += "-std=gnu17"
|
|
|
|
# Uses autoconf but not automake, can't do out-of-tree
|
|
inherit autotools-brokensep pkgconfig
|
|
|
|
# Prune the source tree of libraries that we're using our packaging of, so that
|
|
# ghostscript can't link to them. Can't prune zlib as that's needed for the
|
|
# native tools.
|
|
prune_sources() {
|
|
rm -rf ${S}/jpeg/ ${S}/libpng/ ${S}/tiff/ ${S}/expat/ ${S}/freetype/ ${S}/cups/lib
|
|
}
|
|
do_unpack[postfuncs] += "prune_sources"
|
|
|
|
do_install:append () {
|
|
oe_runmake DESTDIR=${D} install-so
|
|
oe_runmake DESTDIR=${D} install-data
|
|
cp -r ${S}/Resource ${D}${datadir}/ghostscript/${PV}/
|
|
cp -r ${S}/iccprofiles ${D}${datadir}/ghostscript/${PV}/
|
|
}
|
|
|
|
# ghostscript does not supports "arc"
|
|
COMPATIBLE_HOST = "^(?!arc).*"
|
|
|
|
# some entries in NVD uses gpl_ghostscript
|
|
CVE_PRODUCT = "ghostscript gpl_ghostscript"
|
|
|
|
CVE_STATUS[CVE-2023-38560] = "not-applicable-config: PCL isn't part of the Ghostscript release"
|