mirror of
https://git.yoctoproject.org/poky
synced 2026-02-06 00:38:45 +01:00
cec8b230cf
A lot of our recipes had short one-line DESCRIPTION values and no SUMMARY value set. In this case it's much better to just set SUMMARY since DESCRIPTION is defaulted from SUMMARY anyway and then the SUMMARY is at least useful. I also took the opportunity to fix up a lot of the new SUMMARY values, making them concisely explain the function of the recipe / package where possible. (From OE-Core rev: b8feee3cf21f70ba4ec3b822d2f596d4fc02a292) Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
72 lines
2.2 KiB
PHP
72 lines
2.2 KiB
PHP
SUMMARY = "Sanitized set of kernel headers for the C library's use"
|
|
SECTION = "devel"
|
|
LICENSE = "GPLv2"
|
|
|
|
#########################################################################
|
|
#### PLEASE READ
|
|
#########################################################################
|
|
#
|
|
# You're probably looking here thinking you need to create some new copy
|
|
# of linux-libc-headers since you have your own custom kernel. To put
|
|
# this simply, you DO NOT.
|
|
#
|
|
# Why? These headers are used to build the libc. If you customise the
|
|
# headers you are customising the libc and the libc becomes machine
|
|
# specific. Most people do not add custom libc extensions to the kernel
|
|
# and have a machine specific libc.
|
|
#
|
|
# But you have some kernel headers you need for some driver? That is fine
|
|
# but get them from STAGING_KERNEL_DIR where the kernel installs itself.
|
|
# This will make the package using them machine specific but this is much
|
|
# better than having a machine specific C library. This does mean your
|
|
# recipe needs a DEPENDS += "virtual/kernel" but again, that is fine and
|
|
# makes total sense.
|
|
#
|
|
# There can also be a case where your kernel extremely old and you want
|
|
# an older libc ABI for that old kernel. The headers installed by this
|
|
# recipe should still be a standard mainline kernel, not your own custom
|
|
# one.
|
|
#
|
|
# -- RP
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
|
|
|
|
python __anonymous () {
|
|
major = d.getVar("PV",True).split('.')[0]
|
|
if major == "3":
|
|
d.setVar("HEADER_FETCH_VER", "3.0")
|
|
else:
|
|
d.setVar("HEADER_FETCH_VER", "2.6")
|
|
}
|
|
|
|
inherit kernel-arch
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/linux/kernel/v${HEADER_FETCH_VER}/linux-${PV}.tar.bz2"
|
|
|
|
S = "${WORKDIR}/linux-${PV}"
|
|
|
|
do_configure() {
|
|
oe_runmake allnoconfig
|
|
}
|
|
|
|
do_compile () {
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake headers_install INSTALL_HDR_PATH=${D}${exec_prefix}
|
|
# Kernel should not be exporting this header
|
|
rm -f ${D}${exec_prefix}/include/scsi/scsi.h
|
|
|
|
# The ..install.cmd conflicts between various configure runs
|
|
find ${D}${includedir} -name ..install.cmd | xargs rm -f
|
|
}
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|
|
|
|
#DEPENDS = "cross-linkage"
|
|
RDEPENDS_${PN}-dev = ""
|
|
RRECOMMENDS_${PN}-dbg = "${PN}-dev (= ${EXTENDPKGV})"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
DEPENDS += "unifdef-native"
|