mirror of
https://git.yoctoproject.org/poky
synced 2026-09-29 07:36:20 +02:00
c2f785f716
(From OE-Core rev: daf55a989c8bb4a559d75c30ed85b135ec14d5fd) Signed-off-by: Adrian Bunk <bunk@stusta.de> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
47 lines
2.0 KiB
BlitzBasic
47 lines
2.0 KiB
BlitzBasic
SECTION = "devel"
|
|
SUMMARY = "Linux Trace Toolkit KERNEL MODULE"
|
|
DESCRIPTION = "The lttng-modules 2.0 package contains the kernel tracer modules"
|
|
LICENSE = "LGPLv2.1 & GPLv2 & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=c4613d1f8a9587bd7b366191830364b3 \
|
|
file://gpl-2.0.txt;md5=751419260aa954499f7abaabaa882bbe \
|
|
file://lgpl-2.1.txt;md5=243b725d71bb5df4a1e5920b344b86ad \
|
|
"
|
|
|
|
inherit module
|
|
|
|
COMPATIBLE_HOST = '(x86_64|i.86|powerpc|aarch64|mips|nios2|arm|riscv).*-linux'
|
|
|
|
SRC_URI = "https://lttng.org/files/${BPN}/${BPN}-${PV}.tar.bz2 \
|
|
file://Makefile-Do-not-fail-if-CONFIG_TRACEPOINTS-is-not-en.patch \
|
|
file://BUILD_RUNTIME_BUG_ON-vs-gcc7.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "c618fb646514dfc1bf910cfd7cda4256"
|
|
SRC_URI[sha256sum] = "7f91e39b2e8e46d8bbba2b4c8c1614f1fb380611cd1a1fccc1d1859be26112f1"
|
|
|
|
export INSTALL_MOD_DIR="kernel/lttng-modules"
|
|
|
|
EXTRA_OEMAKE += "KERNELDIR='${STAGING_KERNEL_DIR}'"
|
|
|
|
do_install_append() {
|
|
# Delete empty directories to avoid QA failures if no modules were built
|
|
find ${D}/${nonarch_base_libdir} -depth -type d -empty -exec rmdir {} \;
|
|
}
|
|
|
|
python do_package_prepend() {
|
|
if not os.path.exists(os.path.join(d.getVar('D'), d.getVar('nonarch_base_libdir')[1:], 'modules')):
|
|
bb.warn("%s: no modules were created; this may be due to CONFIG_TRACEPOINTS not being enabled in your kernel." % d.getVar('PN'))
|
|
}
|
|
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
LIC_FILES_CHKSUM_class-devupstream = "file://LICENSE;md5=c4613d1f8a9587bd7b366191830364b3"
|
|
DEFAULT_PREFERENCE_class-devupstream = "-1"
|
|
SRC_URI_class-devupstream = "git://git.lttng.org/lttng-modules;branch=stable-2.10 \
|
|
file://Makefile-Do-not-fail-if-CONFIG_TRACEPOINTS-is-not-en.patch \
|
|
file://BUILD_RUNTIME_BUG_ON-vs-gcc7.patch \
|
|
"
|
|
SRCREV_class-devupstream = "624aca5d7507fbd11ea4a1a474c3aa1031bd9a31"
|
|
PV_class-devupstream = "2.10.10+git${SRCPV}"
|
|
S_class-devupstream = "${WORKDIR}/git"
|
|
SRCREV_FORMAT ?= "lttng_git"
|