mirror of
https://git.yoctoproject.org/poky
synced 2026-03-29 23:02:20 +02:00
4faf6e9e07
Source: https://github.com/file MR: 97573, 97578, 97583, 97588 Type: Security Fix Disposition: Backport from https://github.com/file/file ChangeID: 159e532d518623f19ba777c8edc24d2dc7e3a4e9 Description: CVE-2019-8905 is the same fix as CVE-2019-8907 Affects < 5.36.0 Fixes: CVE-2019-8904 CVE-2019-8906 CVE-2019-8906 CVE-2019-8907 (From OE-Core rev: 3d7375eb2e459b891b4ba16c1fc486afbfecef2c) Signed-off-by: Armin Kuster <akuster@mvista.com> Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
54 lines
1.7 KiB
BlitzBasic
54 lines
1.7 KiB
BlitzBasic
SUMMARY = "File classification tool"
|
|
DESCRIPTION = "File attempts to classify files depending \
|
|
on their contents and prints a description if a match is found."
|
|
HOMEPAGE = "http://www.darwinsys.com/file/"
|
|
SECTION = "console/utils"
|
|
|
|
# two clause BSD
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://COPYING;beginline=2;md5=6a7382872edb68d33e1a9398b6e03188"
|
|
|
|
DEPENDS = "zlib file-replacement-native"
|
|
DEPENDS_class-native = "zlib-native"
|
|
|
|
# Blacklist a bogus tag in upstream check
|
|
UPSTREAM_CHECK_GITTAGREGEX = "FILE(?P<pver>(?!6_23).+)"
|
|
|
|
SRC_URI = "git://github.com/file/file.git \
|
|
file://debian-742262.patch \
|
|
file://CVE-2019-8906.patch \
|
|
file://CVE-2019-8904.patch \
|
|
file://CVE-2019-8905_CVE-2019-8907.patch \
|
|
"
|
|
|
|
SRCREV = "315cef2f699da3c31a54bd3c6c6070680fbaf1f5"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools update-alternatives
|
|
|
|
ALTERNATIVE_${PN} = "file"
|
|
ALTERNATIVE_LINK_NAME[file] = "${bindir}/file"
|
|
|
|
EXTRA_OEMAKE_append_class-target = "-e FILE_COMPILE=${STAGING_BINDIR_NATIVE}/file-native/file"
|
|
EXTRA_OEMAKE_append_class-nativesdk = "-e FILE_COMPILE=${STAGING_BINDIR_NATIVE}/file-native/file"
|
|
|
|
CFLAGS_append = " -std=c99"
|
|
|
|
FILES_${PN} += "${datadir}/misc/*.mgc"
|
|
|
|
do_install_append_class-native() {
|
|
create_cmdline_wrapper ${D}/${bindir}/file \
|
|
--magic-file ${datadir}/misc/magic.mgc
|
|
}
|
|
|
|
do_install_append_class-nativesdk() {
|
|
create_cmdline_wrapper ${D}/${bindir}/file \
|
|
--magic-file ${datadir}/misc/magic.mgc
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
PROVIDES_append_class-native = " file-replacement-native"
|
|
# Don't use NATIVE_PACKAGE_PATH_SUFFIX as that hides libmagic from anyone who
|
|
# depends on file-replacement-native.
|
|
bindir_append_class-native = "/file-native"
|