mirror of
https://git.yoctoproject.org/poky
synced 2026-05-05 07:39:49 +02:00
d89034988e
Freeze-breaking upgrade for a security bug fix involving cookie URLs, and a number of static analysis fixes. Drop CVE-2018-12910.patch as this is merged in 2.62.3. (From OE-Core rev: a8098782fab87498026a09c06716b631c77c5ad6) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
35 lines
1.4 KiB
BlitzBasic
35 lines
1.4 KiB
BlitzBasic
SUMMARY = "An HTTP library implementation in C"
|
|
HOMEPAGE = "https://wiki.gnome.org/Projects/libsoup"
|
|
BUGTRACKER = "https://bugzilla.gnome.org/"
|
|
SECTION = "x11/gnome/libs"
|
|
LICENSE = "LGPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2"
|
|
|
|
DEPENDS = "glib-2.0 glib-2.0-native libxml2 sqlite3 intltool-native"
|
|
|
|
SHRT_VER = "${@d.getVar('PV').split('.')[0]}.${@d.getVar('PV').split('.')[1]}"
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/libsoup/${SHRT_VER}/libsoup-${PV}.tar.xz"
|
|
SRC_URI[md5sum] = "dfbf30af5fb6190bfafc5aa6abcc9dce"
|
|
SRC_URI[sha256sum] = "d312ade547495c2093ff8bda61f9b9727a98cfdae339f3263277dd39c0451172"
|
|
|
|
S = "${WORKDIR}/libsoup-${PV}"
|
|
|
|
inherit autotools gettext pkgconfig upstream-version-is-even gobject-introspection gtk-doc
|
|
|
|
# libsoup-gnome is entirely deprecated and just stubs in 2.42 onwards. Disable by default.
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[gnome] = "--with-gnome,--without-gnome"
|
|
PACKAGECONFIG[gssapi] = "--with-gssapi,--without-gssapi,krb5"
|
|
|
|
EXTRA_OECONF = "--disable-vala"
|
|
|
|
# When built without gnome support, libsoup-2.4 will contain only one shared lib
|
|
# and will therefore become subject to renaming by debian.bbclass. Prevent
|
|
# renaming in order to keep the package name consistent regardless of whether
|
|
# gnome support is enabled or disabled.
|
|
DEBIAN_NOAUTONAME_${PN} = "1"
|
|
|
|
# glib-networking is needed for SSL, proxies, etc.
|
|
RRECOMMENDS_${PN} = "glib-networking"
|