mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
47c5f1f1c5
Upgrade to latest 1.20.x release [1]: $ git log --oneline go1.20.13..go1.20.14 90a870f1dc (tag: go1.20.14, origin/release-branch.go1.20) [release-branch.go1.20] go1.20.14 a2f4a5a6e7 [release-branch.go1.20] Revert "crypto/internal/boring: upgrade module to fips-20220613" +1 746a072791 [release-branch.go1.20] crypto/x509: properly gate test on macos version d7df7f4fa0 [release-branch.go1.20] runtime: properly model rwmutex in lock ranking $ git log --oneline go1.20.13..go1.20.14 [1] https://github.com/golang/go/compare/go1.20.13...go1.20.14 (From OE-Core rev: 44f81b6239f0f08877ccd6507c2a81f3650f193b) Signed-off-by: Jose Quaresma <jose.quaresma@foundries.io> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
51 lines
1.4 KiB
BlitzBasic
51 lines
1.4 KiB
BlitzBasic
# This recipe is for bootstrapping our go-cross from a prebuilt binary of Go from golang.org.
|
|
|
|
SUMMARY = "Go programming language compiler (upstream binary for bootstrap)"
|
|
HOMEPAGE = " http://golang.org/"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=5d4950ecb7b26d2c5e4e7b4e0dd74707"
|
|
|
|
PROVIDES = "go-native"
|
|
|
|
# Checksums available at https://go.dev/dl/
|
|
SRC_URI = "https://dl.google.com/go/go${PV}.${BUILD_GOOS}-${BUILD_GOARCH}.tar.gz;name=go_${BUILD_GOTUPLE}"
|
|
SRC_URI[go_linux_amd64.sha256sum] = "ff445e48af27f93f66bd949ae060d97991c83e11289009d311f25426258f9c44"
|
|
SRC_URI[go_linux_arm64.sha256sum] = "2096507509a98782850d1f0669786c09727053e9fe3c92b03c0d96f48700282b"
|
|
SRC_URI[go_linux_ppc64le.sha256sum] = "237b1da9b65629a9b0fcf1f3ca75b4c84ef55fca1fc3eadf1681da7bbcb2e9cd"
|
|
|
|
UPSTREAM_CHECK_URI = "https://golang.org/dl/"
|
|
UPSTREAM_CHECK_REGEX = "go(?P<pver>\d+(\.\d+)+)\.linux"
|
|
|
|
CVE_PRODUCT = "golang:go"
|
|
|
|
S = "${WORKDIR}/go"
|
|
|
|
inherit goarch native
|
|
|
|
do_compile() {
|
|
:
|
|
}
|
|
|
|
make_wrapper() {
|
|
rm -f ${D}${bindir}/$1
|
|
cat <<END >${D}${bindir}/$1
|
|
#!/bin/bash
|
|
here=\`dirname \$0\`
|
|
export GOROOT="${GOROOT:-\`readlink -f \$here/../lib/go\`}"
|
|
\$here/../lib/go/bin/$1 "\$@"
|
|
END
|
|
chmod +x ${D}${bindir}/$1
|
|
}
|
|
|
|
do_install() {
|
|
find ${S} -depth -type d -name testdata -exec rm -rf {} +
|
|
|
|
install -d ${D}${bindir} ${D}${libdir}/go
|
|
cp --preserve=mode,timestamps -R ${S}/ ${D}${libdir}/
|
|
|
|
for f in ${S}/bin/*
|
|
do
|
|
make_wrapper `basename $f`
|
|
done
|
|
}
|