mirror of
https://git.yoctoproject.org/poky
synced 2026-03-11 01:39:40 +01:00
47d3c858f5
Integrating the following commit(s) to linux-yocto/5.15:
07a63f760793 netfilter: conntrack: avoid useless indirection during conntrack destruction
(From OE-Core rev: 2aaf2429474da762d305d6fb70996b5502c879c7)
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
68 lines
3.2 KiB
BlitzBasic
68 lines
3.2 KiB
BlitzBasic
KBRANCH ?= "v5.15/standard/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# board specific branches
|
|
KBRANCH:qemuarm ?= "v5.15/standard/arm-versatile-926ejs"
|
|
KBRANCH:qemuarm64 ?= "v5.15/standard/qemuarm64"
|
|
KBRANCH:qemumips ?= "v5.15/standard/mti-malta32"
|
|
KBRANCH:qemuppc ?= "v5.15/standard/qemuppc"
|
|
KBRANCH:qemuriscv64 ?= "v5.15/standard/base"
|
|
KBRANCH:qemuriscv32 ?= "v5.15/standard/base"
|
|
KBRANCH:qemux86 ?= "v5.15/standard/base"
|
|
KBRANCH:qemux86-64 ?= "v5.15/standard/base"
|
|
KBRANCH:qemumips64 ?= "v5.15/standard/mti-malta64"
|
|
|
|
SRCREV_machine:qemuarm ?= "2c5f632df378c23226fdb89fe36ad83c05d8da01"
|
|
SRCREV_machine:qemuarm64 ?= "4a6d3cff7783b6d6f0c8c09de3158cffe8fa97af"
|
|
SRCREV_machine:qemumips ?= "b8cca873d9d28cb48884ce4aa69983fe36867309"
|
|
SRCREV_machine:qemuppc ?= "b0a8af64b0b46184583f8eb05a3c7b038d5484bf"
|
|
SRCREV_machine:qemuriscv64 ?= "07a63f760793c64abe99674f067ae0643fdd2314"
|
|
SRCREV_machine:qemuriscv32 ?= "07a63f760793c64abe99674f067ae0643fdd2314"
|
|
SRCREV_machine:qemux86 ?= "07a63f760793c64abe99674f067ae0643fdd2314"
|
|
SRCREV_machine:qemux86-64 ?= "07a63f760793c64abe99674f067ae0643fdd2314"
|
|
SRCREV_machine:qemumips64 ?= "6456900204c039e30e383eebb27b97cffacf420a"
|
|
SRCREV_machine ?= "07a63f760793c64abe99674f067ae0643fdd2314"
|
|
SRCREV_meta ?= "cb8938bc9d6b4575a1cd0072106b9720648ed0ab"
|
|
|
|
# set your preferred provider of linux-yocto to 'linux-yocto-upstream', and you'll
|
|
# get the <version>/base branch, which is pure upstream -stable, and the same
|
|
# meta SRCREV as the linux-yocto-standard builds. Select your version using the
|
|
# normal PREFERRED_VERSION settings.
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRCREV_machine:class-devupstream ?= "06f50ca83ace219cb72213369d2be05bb0dd337e"
|
|
PN:class-devupstream = "linux-yocto-upstream"
|
|
KBRANCH:class-devupstream = "v5.15/base"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH}; \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.15;destsuffix=${KMETA}"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
LINUX_VERSION ?= "5.15.33"
|
|
|
|
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
|
DEPENDS += "openssl-native util-linux-native"
|
|
DEPENDS += "gmp-native libmpc-native"
|
|
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "1"
|
|
|
|
KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
|
|
|
|
COMPATIBLE_MACHINE = "qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
|
|
KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
|
|
KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"
|
|
|
|
INSANE_SKIP:kernel-vmlinux:qemuppc64 = "textrel"
|
|
|