mirror of
https://git.yoctoproject.org/poky
synced 2026-05-05 07:39:49 +02:00
ed9971d58d
Drop remove.ldconfig.call.patch, as it's easier to just set LDCONFIG=true. Pass uname=GNU via the documented configure option instead of undocumented environment variable. Rename zlib-1.2.11/ to just zlib/ as we don't ship multiple versions. Send ldflags-tests.patch upstream and update Upstream-Status. (From OE-Core rev: 344090a549284d0a1af065ff4cc3038bff8ecfea) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
67 lines
1.8 KiB
BlitzBasic
67 lines
1.8 KiB
BlitzBasic
SUMMARY = "Zlib Compression Library"
|
|
DESCRIPTION = "Zlib is a general-purpose, patent-free, lossless data compression \
|
|
library which is used by many different programs."
|
|
HOMEPAGE = "http://zlib.net/"
|
|
SECTION = "libs"
|
|
LICENSE = "Zlib"
|
|
LIC_FILES_CHKSUM = "file://zlib.h;beginline=6;endline=23;md5=5377232268e952e9ef63bc555f7aa6c0"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/libpng/${BPN}/${PV}/${BPN}-${PV}.tar.xz \
|
|
file://Makefile-runtests.patch \
|
|
file://ldflags-tests.patch \
|
|
file://run-ptest \
|
|
"
|
|
UPSTREAM_CHECK_URI = "http://zlib.net/"
|
|
|
|
SRC_URI[md5sum] = "85adef240c5f370b308da8c938951a68"
|
|
SRC_URI[sha256sum] = "4ff941449631ace0d4d203e3483be9dbc9da454084111f97ea0a2114e19bf066"
|
|
|
|
CFLAGS += "-D_REENTRANT"
|
|
|
|
RDEPENDS_${PN}-ptest += "make"
|
|
|
|
inherit ptest
|
|
|
|
do_configure() {
|
|
LDCONFIG=true ./configure --prefix=${prefix} --shared --libdir=${libdir} --uname=GNU
|
|
}
|
|
|
|
do_compile() {
|
|
oe_runmake shared
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake test
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake DESTDIR=${D} install
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install ${B}/Makefile ${D}${PTEST_PATH}
|
|
install ${B}/example ${D}${PTEST_PATH}
|
|
install ${B}/minigzip ${D}${PTEST_PATH}
|
|
install ${B}/examplesh ${D}${PTEST_PATH}
|
|
install ${B}/minigzipsh ${D}${PTEST_PATH}
|
|
|
|
# Remove buildhost references...
|
|
sed -i -e "s,--sysroot=${STAGING_DIR_TARGET},,g" \
|
|
-e 's|${DEBUG_PREFIX_MAP}||g' \
|
|
${D}${PTEST_PATH}/Makefile
|
|
}
|
|
|
|
# Move zlib shared libraries for target builds to $base_libdir so the library
|
|
# can be used in early boot before $prefix is mounted.
|
|
do_install_append_class-target() {
|
|
if [ ${base_libdir} != ${libdir} ]
|
|
then
|
|
mkdir -p ${D}/${base_libdir}
|
|
mv ${D}/${libdir}/libz.so.* ${D}/${base_libdir}
|
|
libname=`readlink ${D}/${libdir}/libz.so`
|
|
ln -sf ${@oe.path.relative("${libdir}", "${base_libdir}")}/$libname ${D}${libdir}/libz.so
|
|
fi
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|