mirror of
https://git.yoctoproject.org/poky
synced 2026-04-01 23:02:21 +02:00
e6200912a8
lsof 4.89 archive has been moved to OLD directory and turned into tar.gz, so update SRC_URI and checksums. (From OE-Core rev: 12482854ed9012f309fc8dfa28169f84003f9e63) Signed-off-by: Ovidiu Panait <ovidiu.panait@windriver.com> Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
65 lines
2.0 KiB
BlitzBasic
65 lines
2.0 KiB
BlitzBasic
SUMMARY = "LiSt Open Files tool"
|
|
DESCRIPTION = "Lsof is a Unix-specific diagnostic tool. \
|
|
Its name stands for LiSt Open Files, and it does just that."
|
|
HOMEPAGE = "http://people.freebsd.org/~abe/"
|
|
SECTION = "devel"
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://00README;beginline=645;endline=679;md5=964df275d26429ba3b39dbb9f205172a"
|
|
|
|
# Upstream lsof releases are hosted on an ftp server which times out download
|
|
# attempts from hosts for which it can not perform a DNS reverse-lookup (See:
|
|
# https://people.freebsd.org/~abe/ ). http://www.mirrorservice.org seems to be
|
|
# the most commonly used alternative.
|
|
|
|
SRC_URI = "http://www.mirrorservice.org/sites/lsof.itap.purdue.edu/pub/tools/unix/lsof/OLD/lsof_${PV}.tar.gz \
|
|
file://lsof-remove-host-information.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "8afbaff3ee308edc130bdc5df0801c8f"
|
|
SRC_URI[sha256sum] = "5d08da7ebe049c9d9a6472d6afb81aa5af54c4733a3f8822cbc22b57867633c9"
|
|
|
|
LOCALSRC = "file://${WORKDIR}/lsof_${PV}/lsof_${PV}_src.tar"
|
|
|
|
S = "${WORKDIR}/lsof_${PV}_src"
|
|
|
|
python do_unpack () {
|
|
# temporarily change S for unpack
|
|
# of lsof_${PV}
|
|
s = d.getVar('S', False)
|
|
d.setVar('S', '${WORKDIR}/lsof_${PV}')
|
|
bb.build.exec_func('base_do_unpack', d)
|
|
# temporarily change SRC_URI for unpack
|
|
# of lsof_${PV}_src
|
|
src_uri = d.getVar('SRC_URI', False)
|
|
d.setVar('SRC_URI', '${LOCALSRC}')
|
|
d.setVar('S', s)
|
|
bb.build.exec_func('base_do_unpack', d)
|
|
d.setVar('SRC_URI', src_uri)
|
|
}
|
|
|
|
export LSOF_INCLUDE = "${STAGING_INCDIR}"
|
|
|
|
do_configure () {
|
|
export LSOF_AR="${AR} cr"
|
|
export LSOF_RANLIB="${RANLIB}"
|
|
if [ "x${GLIBCVERSION}" != "x" ]; then
|
|
LINUX_CLIB=`echo ${GLIBCVERSION} |sed -e 's,\.,,g'`
|
|
LINUX_CLIB="-DGLIBCV=${LINUX_CLIB}"
|
|
export LINUX_CLIB
|
|
fi
|
|
yes | ./Configure linux
|
|
}
|
|
|
|
export I = "${STAGING_INCDIR}"
|
|
export L = "${STAGING_INCDIR}"
|
|
|
|
do_compile () {
|
|
oe_runmake 'CC=${CC}' 'CFGL=${LDFLAGS} -L./lib -llsof' 'DEBUG=' 'INCL=${CFLAGS}'
|
|
}
|
|
|
|
do_install () {
|
|
install -d ${D}${sbindir} ${D}${mandir}/man8
|
|
install -m 0755 lsof ${D}${sbindir}/lsof
|
|
install -m 0644 lsof.8 ${D}${mandir}/man8/lsof.8
|
|
}
|