mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 00:32:12 +02:00
f3ad36d15c
- Rebased fix-rs6000-crt0.patch - Patch fix_makefile_include_arm_h.patch is no longer required, the newlib header dependency has been fixed upstream at 26f9cfd7 - LICENSE checksum change due to: - Adding SPDX identifier - Deleted Phoenix Systems from License and updated each licenses numbers accordingly. - Add a dummy limits.h header, to make the improved preprocessor checks happy during configure. - Add a patch for libgloss to maintain current behavior of TCLIBC=newlib by making libgloss DEPEND on newlib and use its installed headers. - Switch to git fetcher to simplify fetching the sources and avoid future issues due to the way newlib release snapshots were being published. (From OE-Core rev: 1c9cbb27dfe37ca4574c4285fb03ce394dee5ed1) Signed-off-by: Alejandro Enedino Hernandez Samaniego <alejandro@enedino.org> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
37 lines
1.0 KiB
BlitzBasic
37 lines
1.0 KiB
BlitzBasic
require newlib.inc
|
|
|
|
DEPENDS += "newlib"
|
|
|
|
FILESEXTRAPATHS:prepend := "${THISDIR}/libgloss:"
|
|
|
|
SRC_URI:append = " file://libgloss-build-without-nostdinc.patch"
|
|
SRC_URI:append:powerpc = " file://fix-rs6000-crt0.patch"
|
|
SRC_URI:append:powerpc = " file://fix-rs6000-cflags.patch"
|
|
|
|
do_configure() {
|
|
${S}/libgloss/configure ${EXTRA_OECONF}
|
|
}
|
|
|
|
do_install:prepend() {
|
|
# install doesn't create this itself, avoid install error
|
|
install -d ${D}${prefix}/${TARGET_SYS}/lib
|
|
}
|
|
|
|
do_install:append() {
|
|
# Move libs to default directories so they can be picked up later
|
|
install -d ${D}${libdir}
|
|
mv -v ${D}${prefix}/${TARGET_SYS}/lib/* ${D}${libdir}
|
|
|
|
# Remove original directory
|
|
rmdir -p --ignore-fail-on-non-empty ${D}${prefix}/${TARGET_SYS}/lib
|
|
}
|
|
|
|
# Split packages correctly
|
|
FILES:${PN} += "${libdir}/*.ld ${libdir}/*.specs"
|
|
FILES:${PN}-dev += "${libdir}/cpu-init/*"
|
|
# RiscV installation moved the syscall header to this location
|
|
FILES:${PN}-dev += "${prefix}/${TARGET_SYS}/include/machine/*.h"
|
|
|
|
INHIBIT_PACKAGE_STRIP = "1"
|
|
INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
|