mirror of
https://git.yoctoproject.org/poky
synced 2026-03-28 19:02:22 +01:00
95ed7d9909
LZMA isn't supported by the mainline kernel driver, so there's no real point in enabling it. Disable LZO by default, as LZO is very obsolete (last released in 2017) and there are better algorithms available. Move xattr to the end so it's separate from the compression algorithms. (From OE-Core rev: 6f65d9372ec639491920fd48df76dfea8afdbfd9) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
1.5 KiB
BlitzBasic
46 lines
1.5 KiB
BlitzBasic
SUMMARY = "Tools for manipulating SquashFS filesystems"
|
|
HOMEPAGE = "https://github.com/plougher/squashfs-tools"
|
|
DESCRIPTION = "Tools to create and extract Squashfs filesystems."
|
|
SECTION = "base"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
SRC_URI = "git://github.com/plougher/squashfs-tools.git;protocol=https;branch=master;tag=${PV} \
|
|
file://pid.patch \
|
|
file://thread.patch"
|
|
SRCREV = "2e87d42ed089dc31990d83eeb07437b9d085d6d1"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>(\d+(\.\d+)+))"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
EXTRA_OEMAKE = "${PACKAGECONFIG_CONFARGS}"
|
|
|
|
PACKAGECONFIG ??= "gzip lz4 xz zstd xattr"
|
|
PACKAGECONFIG[gzip] = "GZIP_SUPPORT=1,GZIP_SUPPORT=0,zlib"
|
|
PACKAGECONFIG[xz] = "XZ_SUPPORT=1,XZ_SUPPORT=0,xz"
|
|
PACKAGECONFIG[lzo] = "LZO_SUPPORT=1,LZO_SUPPORT=0,lzo"
|
|
PACKAGECONFIG[lz4] = "LZ4_SUPPORT=1,LZ4_SUPPORT=0,lz4"
|
|
PACKAGECONFIG[lzma] = "LZMA_XZ_SUPPORT=1,LZMA_XZ_SUPPORT=0,xz"
|
|
PACKAGECONFIG[zstd] = "ZSTD_SUPPORT=1,ZSTD_SUPPORT=0,zstd"
|
|
PACKAGECONFIG[xattr] = "XATTR_SUPPORT=1,XATTR_SUPPORT=0,attr"
|
|
|
|
do_compile() {
|
|
oe_runmake -C ${S}/squashfs-tools all
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake -C ${S}/squashfs-tools install INSTALL_PREFIX=${D}${prefix} INSTALL_MANPAGES_DIR=${D}${datadir}/man/man1
|
|
|
|
install -d "${D}${includedir}"
|
|
install -m 0644 "${S}"/squashfs-tools/squashfs_fs.h "${D}${includedir}"
|
|
}
|
|
|
|
ARM_INSTRUCTION_SET:armv4 = "arm"
|
|
ARM_INSTRUCTION_SET:armv5 = "arm"
|
|
ARM_INSTRUCTION_SET:armv6 = "arm"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
CVE_PRODUCT = "squashfs"
|