mirror of
https://git.yoctoproject.org/poky
synced 2026-03-29 14:02:22 +02:00
e65d0d156d
The previous one wasn't particularly readable, and assumed a particular relationship between S and B. The new one also works when S is in UNPACKDIR, or anywhere else. (From OE-Core rev: 584b039fe688ba85fb19b48f2c7209452e248c00) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
56 lines
2.3 KiB
BlitzBasic
56 lines
2.3 KiB
BlitzBasic
SUMMARY = "System call tracing tool"
|
|
HOMEPAGE = "http://strace.io"
|
|
DESCRIPTION = "strace is a diagnostic, debugging and instructional userspace utility for Linux. It is used to monitor and tamper with interactions between processes and the Linux kernel, which include system calls, signal deliveries, and changes of process state."
|
|
SECTION = "console/utils"
|
|
LICENSE = "LGPL-2.1-or-later & GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=1efaf30bb0084b4a17a6f55f9cbcd25b"
|
|
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/strace-${PV}.tar.xz \
|
|
file://update-gawk-paths.patch \
|
|
file://Makefile-ptest.patch \
|
|
file://run-ptest \
|
|
file://ptest-spacesave.patch \
|
|
file://0001-strace-fix-reproducibilty-issues.patch \
|
|
file://skip-load.patch \
|
|
file://0001-configure-Use-autoconf-macro-to-detect-largefile-sup.patch \
|
|
file://0002-tests-Replace-off64_t-with-off_t.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "8552dfab08abc22a0f2048c98fd9541fd4d71b6882507952780dab7c7c512f51"
|
|
|
|
|
|
inherit autotools github-releases ptest
|
|
|
|
# Not yet ported to rv32
|
|
COMPATIBLE_HOST:riscv32 = "null"
|
|
|
|
# bluez is not enabled by default due to build dependency creep in smaller builds
|
|
# like core-image-minimal leading to significantly more tasks being executed
|
|
PACKAGECONFIG[bluez] = "ac_cv_header_bluetooth_bluetooth_h=yes,ac_cv_header_bluetooth_bluetooth_h=no,bluez5"
|
|
PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind"
|
|
|
|
EXTRA_OECONF += "--enable-mpers=no --disable-gcc-Werror"
|
|
|
|
CFLAGS:append:libc-musl = " -Dsigcontext_struct=sigcontext"
|
|
|
|
TESTDIR = "tests"
|
|
PTEST_BUILD_HOST_PATTERN = "^(DEB_CHANGELOGTIME|RPM_CHANGELOGTIME|WARN_CFLAGS_FOR_BUILD|LDFLAGS_FOR_BUILD)"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C ${TESTDIR} buildtest-TESTS
|
|
}
|
|
|
|
do_install_ptest() {
|
|
oe_runmake -C ${TESTDIR} install-ptest BUILDDIR=${B} DESTDIR=${D}${PTEST_PATH} TESTDIR=${TESTDIR}
|
|
mkdir -p ${D}${PTEST_PATH}/build-aux
|
|
mkdir -p ${D}${PTEST_PATH}/src
|
|
install -m 755 ${S}/build-aux/test-driver ${D}${PTEST_PATH}/build-aux/
|
|
install -m 644 ${B}/src/config.h ${D}${PTEST_PATH}/src/
|
|
sed -e 's/^srcdir = .*/srcdir = ..\/..\/ptest\/tests/' \
|
|
-e "/^TEST_LOG_DRIVER =/s|(top_srcdir)|(top_builddir)|" \
|
|
-i ${D}/${PTEST_PATH}/${TESTDIR}/Makefile
|
|
}
|
|
|
|
RDEPENDS:${PN}-ptest += "make coreutils grep gawk sed locale-base-en-us"
|
|
|
|
BBCLASSEXTEND = "native"
|