mirror of
https://git.yoctoproject.org/poky
synced 2026-05-04 22:39:49 +02:00
543567bb8a
Github has announced there will be no more git:// fetching from their servers: https://github.blog/2021-09-01-improving-git-protocol-security-github/#no-more-unauthenticated-git and they're about to start having brownout periods to encourage people to update. This runs the conversion script over OE-Core to update our urls to use https instead of git. (From OE-Core rev: 8b83eddda83327d25247bb9b61a049b0a8698a45) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit b37b61e9a1e448a34957db9ae39285d21352552e) Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
33 lines
1.3 KiB
BlitzBasic
33 lines
1.3 KiB
BlitzBasic
SUMMARY = "Vulkan Utilities and Tools"
|
|
DESCRIPTION = "Assist development by enabling developers to verify their applications correct use of the Vulkan API."
|
|
HOMEPAGE = "https://www.khronos.org/vulkan/"
|
|
BUGTRACKER = "https://github.com/KhronosGroup/Vulkan-Tools"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=3b83ef96387f14655fc854ddc3c6bd57"
|
|
SRC_URI = "git://github.com/KhronosGroup/Vulkan-Tools.git;branch=sdk-1.2.182;protocol=https"
|
|
SRCREV = "9d3305731c3be8de05c9f223a79959d448506a37"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit cmake features_check
|
|
ANY_OF_DISTRO_FEATURES = "x11 wayland"
|
|
REQUIRED_DISTRO_FEATURES = "vulkan"
|
|
|
|
DEPENDS += "vulkan-headers vulkan-loader"
|
|
|
|
EXTRA_OECMAKE = "\
|
|
-DBUILD_TESTS=OFF \
|
|
-DBUILD_CUBE=OFF \
|
|
-DPYTHON_EXECUTABLE=${HOSTTOOLS_DIR}/python3 \
|
|
"
|
|
|
|
# must choose x11 or wayland or both
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'wayland x11', d)}"
|
|
|
|
PACKAGECONFIG[x11] = "-DBUILD_WSI_XLIB_SUPPORT=ON -DBUILD_WSI_XCB_SUPPORT=ON, -DBUILD_WSI_XLIB_SUPPORT=OFF -DBUILD_WSI_XCB_SUPPORT=OFF, libxcb libx11 libxrandr"
|
|
PACKAGECONFIG[wayland] = "-DBUILD_WSI_WAYLAND_SUPPORT=ON, -DBUILD_WSI_WAYLAND_SUPPORT=OFF, wayland"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "sdk-(?P<pver>\d+(\.\d+)+)"
|