mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 18:32:13 +02:00
ddedab4d1d
When the user is root, run quilt ptest, the faildiff.test failed. Because in the faildiff.test, we drop the read permission of the file test.txt, we can't "quilt refresh" as normal user, so we got the following: >~ .*diff:test\.txt: Permission denied > Diff failed on file 'test.txt', aborting But when the user is root, we can access the file, so we got the following: > Nothing in patch patchs/test.diff So the faildiff.test was failed. We should create a normal user to run the ptest in the run-ptest scripts to slove the problem. (From OE-Core rev: f7d52d12f943b9e1f79b32758308607036d6a760) Signed-off-by: Dengke Du <dengke.du@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
65 lines
2.1 KiB
PHP
65 lines
2.1 KiB
PHP
SUMMARY = "Tool for working with series of patches"
|
|
HOMEPAGE = "http://savannah.nongnu.org/projects/quilt/"
|
|
SECTION = "devel"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
|
|
|
|
SRC_URI = "${SAVANNAH_GNU_MIRROR}/quilt/quilt-${PV}.tar.gz \
|
|
file://install.patch \
|
|
file://run-ptest \
|
|
file://Makefile \
|
|
file://test.sh \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "fc0310db5868a0873d602d4332a76d43"
|
|
SRC_URI[sha256sum] = "c4bfd3282214a288e8d3e921ae4d52e73e24c4fead72b5446752adee99a7affd"
|
|
|
|
inherit autotools-brokensep ptest
|
|
|
|
EXTRA_OECONF_darwin += "--without-date \
|
|
--without-getopt \
|
|
"
|
|
|
|
CLEANBROKEN = "1"
|
|
|
|
PACKAGES += "guards guards-doc"
|
|
FILES_${PN} = "${sysconfdir} ${datadir}/quilt \
|
|
${bindir}/quilt ${libdir}/quilt"
|
|
FILES_guards = "${bindir}/guards"
|
|
FILES_${PN}-doc = "${mandir}/man1/quilt.1 ${docdir}/${BPN}"
|
|
FILES_guards-doc = "${mandir}/man1/guards.1"
|
|
|
|
RDEPENDS_${PN} = "bash"
|
|
|
|
EXTRA_OE_MAKE_ARGS_darwin ?= ""
|
|
EXTRA_OE_MAKE_ARGS ?= "BUILD_ROOT=${D}"
|
|
|
|
CACHED_CONFIGUREVARS += "ac_cv_path_BASH=/bin/bash"
|
|
|
|
# quilt ignores DESTDIR
|
|
do_install () {
|
|
oe_runmake ${EXTRA_OE_MAKE_ARGS} install
|
|
# cleanup unpackaged files
|
|
rm -rf ${D}/${datadir}/emacs
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake bin/patch-wrapper test/.depend
|
|
}
|
|
|
|
do_install_ptest() {
|
|
tar -cf - bin/ --exclude \*.in | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
tar -cf - compat/ --exclude \*.in | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
tar -cf - quilt/ --exclude \*.in | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
tar -cf - test/ --exclude mail.test --exclude delete.test | ( cd ${D}${PTEST_PATH} && tar -xf - && chmod 777 test)
|
|
cp ${WORKDIR}/Makefile ${D}${PTEST_PATH}
|
|
cp ${WORKDIR}/test.sh ${D}${PTEST_PATH}
|
|
}
|
|
|
|
RDEPENDS_${PN}-ptest = "make file sed gawk diffutils findutils ed perl \
|
|
perl-module-filehandle perl-module-getopt-std \
|
|
perl-module-posix perl-module-file-temp \
|
|
perl-module-text-parsewords perl-module-overloading \
|
|
bash util-linux-getopt \
|
|
"
|