mirror of
https://git.yoctoproject.org/poky
synced 2026-02-26 19:39:40 +01:00
6606a86979
Fixed:
MACHINE = "qemux86-64"
require conf/multilib.conf
MULTILIBS = "multilib:lib32"
DEFAULTTUNE_virtclass-multilib-lib32 = "x86"
$ bitbake ovmf lib32-ovmf
[snip]
ERROR: ovmf-edk2-stable201905-r0 do_deploy_setscene: The recipe ovmf is trying to install files into a shared area when those files already exist.
Those files and their manifest location are:
/buildarea1/lyang1/rebase-work/test_cc/tmp-glibc/deploy/images/qemux86-64/OvmfPkKek1.key
(matched in manifest-qemux86_64-lib32-ovmf.deploy)
[snip]
Add it NON_MULTILIB_RECIPES to fix the problem since it is a firmware, build
multilib for it doens't make much sense.
(From OE-Core rev: 5c685f55ccba9d47a79e8798903b30b90bdf03c6)
Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
33 lines
1.3 KiB
Plaintext
33 lines
1.3 KiB
Plaintext
|
|
baselib = "${@d.getVar('BASE_LIB_tune-' + (d.getVar('DEFAULTTUNE') or 'INVALID')) or d.getVar('BASELIB')}"
|
|
|
|
MULTILIB_VARIANTS = "${@extend_variants(d,'MULTILIBS','multilib')}"
|
|
MULTILIB_SAVE_VARNAME = "DEFAULTTUNE TARGET_ARCH TARGET_SYS TARGET_VENDOR"
|
|
|
|
MULTILIBS ??= "multilib:lib32"
|
|
|
|
STAGING_DIR_HOST = "${WORKDIR}/${MLPREFIX}recipe-sysroot"
|
|
STAGING_DIR_TARGET = "${WORKDIR}/${MLPREFIX}recipe-sysroot"
|
|
RECIPE_SYSROOT = "${WORKDIR}/${MLPREFIX}recipe-sysroot"
|
|
|
|
INHERIT += "multilib_global"
|
|
|
|
BBCLASSEXTEND_append = " ${MULTILIBS}"
|
|
|
|
MULTILIB_GLOBAL_VARIANTS ?= "lib32 lib64 libx32"
|
|
|
|
OPKG_ARGS_append = " --force-maintainer --force-overwrite"
|
|
|
|
# When multilib is enabled, allarch recipes will be installed into the MACHINE
|
|
# sysroot, not MLPREFIXMACHINE. This means that anything using pkg-config to
|
|
# find an allarch pkgconfig file will fail as the PKG_CONFIG_PATH only looks
|
|
# inside the multilib sysroot. Fix this by explicitly adding the MACHINE's
|
|
# architecture-independent pkgconfig location to PKG_CONFIG_PATH.
|
|
PKG_CONFIG_PATH .= ":${WORKDIR}/recipe-sysroot/${datadir}/pkgconfig"
|
|
PKG_CONFIG_PATH[vardepsexclude] = "datadir WORKDIR"
|
|
PKG_CONFIG_PATH[vardepvalueexclude] = ":${WORKDIR}/recipe-sysroot/${datadir}/pkgconfig"
|
|
|
|
# These recipes don't need multilib variants, the ${BPN} PROVDES/RPROVDES
|
|
# ${MLPREFIX}${BPN}
|
|
NON_MULTILIB_RECIPES = "grub grub-efi make-mod-scripts ovmf"
|