mirror of
https://git.yoctoproject.org/poky
synced 2026-03-19 13:49:41 +01:00
cc24a0ff76
To solve the following GNU_HASH error: ERROR: opensbi-1.4-r0 do_package_qa: QA Issue: File /share/opensbi/lp64/generic/firmware/fw_dynamic.elf in package opensbi doesn't have GNU_HASH (didn't pass LDFLAGS?) File /share/opensbi/lp64/generic/firmware/fw_payload.elf in package opensbi doesn't have GNU_HASH (didn't pass LDFLAGS?) File /share/opensbi/lp64/generic/firmware/fw_jump.elf in package opensbi doesn't have GNU_HASH (didn't pass LDFLAGS?) [ldflags] [YOCTO #15370] -- https://bugzilla.yoctoproject.org/show_bug.cgi?id=15370 (From OE-Core rev: b82e1e99feb8b0d70ff4c4bcac67336d562d2e53) Signed-off-by: Thomas Perrot <thomas.perrot@bootlin.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
48 lines
2.0 KiB
BlitzBasic
48 lines
2.0 KiB
BlitzBasic
SUMMARY = "RISC-V Open Source Supervisor Binary Interface (OpenSBI)"
|
|
DESCRIPTION = "OpenSBI aims to provide an open-source and extensible implementation of the RISC-V SBI specification for a platform specific firmware (M-mode) and a general purpose OS, hypervisor or bootloader (S-mode or HS-mode). OpenSBI implementation can be easily extended by RISC-V platform or System-on-Chip vendors to fit a particular hadware configuration."
|
|
HOMEPAGE = "https://github.com/riscv/opensbi"
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING.BSD;md5=42dd9555eb177f35150cf9aa240b61e5"
|
|
|
|
require opensbi-payloads.inc
|
|
|
|
inherit autotools-brokensep deploy
|
|
|
|
SRCREV = "a2b255b88918715173942f2c5e1f97ac9e90c877"
|
|
SRC_URI = "git://github.com/riscv/opensbi.git;branch=master;protocol=https"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
TARGET_CC_ARCH += "${LDFLAGS}"
|
|
|
|
EXTRA_OEMAKE += "PLATFORM=${RISCV_SBI_PLAT} I=${D} FW_PIC=y CLANG_TARGET= "
|
|
# If RISCV_SBI_PAYLOAD is set then include it as a payload
|
|
EXTRA_OEMAKE:append = " ${@riscv_get_extra_oemake_image(d)}"
|
|
EXTRA_OEMAKE:append = " ${@riscv_get_extra_oemake_fdt(d)}"
|
|
|
|
# Required if specifying a custom payload
|
|
do_compile[depends] += "${@riscv_get_do_compile_depends(d)}"
|
|
|
|
do_install:append() {
|
|
# In the future these might be required as a dependency for other packages.
|
|
# At the moment just delete them to avoid warnings
|
|
rm -r ${D}/include
|
|
rm -r ${D}/lib*
|
|
rm -r ${D}/share/opensbi/*/${RISCV_SBI_PLAT}/firmware/payloads
|
|
}
|
|
|
|
do_deploy () {
|
|
install -m 755 ${D}/share/opensbi/*/${RISCV_SBI_PLAT}/firmware/fw_payload.* ${DEPLOYDIR}/
|
|
install -m 755 ${D}/share/opensbi/*/${RISCV_SBI_PLAT}/firmware/fw_jump.* ${DEPLOYDIR}/
|
|
install -m 755 ${D}/share/opensbi/*/${RISCV_SBI_PLAT}/firmware/fw_dynamic.* ${DEPLOYDIR}/
|
|
}
|
|
|
|
addtask deploy before do_build after do_install
|
|
|
|
FILES:${PN} += "/share/opensbi/*/${RISCV_SBI_PLAT}/firmware/fw_jump.*"
|
|
FILES:${PN} += "/share/opensbi/*/${RISCV_SBI_PLAT}/firmware/fw_payload.*"
|
|
FILES:${PN} += "/share/opensbi/*/${RISCV_SBI_PLAT}/firmware/fw_dynamic.*"
|
|
|
|
COMPATIBLE_HOST = "(riscv64|riscv32).*"
|
|
INHIBIT_PACKAGE_STRIP = "1"
|