mirror of
https://git.yoctoproject.org/poky
synced 2026-04-30 03:32:12 +02:00
f7accf6941
configure.patch refreshed for 3.11.1 Changelog: =========== * Fixed wrong API version in lib/pci.h. * Updated README.Windows. * Fix compilation on Windows. * update-pciids now supports XZ compression. If libpci is configured with support for compression, all downloaded files are recompressed as gzip. Otherwise they are stored as plain text. * update-pciids now sends itself as the User-Agent. * Added a pcilmr utility for PCIe lane margining. * Re-factored access to i386 ports on all relevant platforms. * Added i386 port access on OpenBSD. * Back-ends for Windows received many bug fixes and improvements. * ECAM back-end now scans ACPI and BIOS memory faster. * Linux systems without pread/pwrite are no longer supported as they are hopefully long gone. This helps avoid the tricky check for presence of pread which was found to fail on musl libc. * Improved decoding of PCIe control and status registers. * Decoding of CXL capabilities now supports up to CXL 3.0. * lspci now displays interrupt message numbers consistently across different capabilities. * Cache of IDs resolved via DNS, which was located in ~/.pci-ids by default, is now stored according to the XDG base directory specification in $XDG_CACHE_HOME/pci-ids. * All source files now have SPDX license identifiers. * Internal: The "aux" fields of structs pci_access and pci_dev reserved for use by back-ends were renamed to backend_data to better reflect their meaning. * As usually, various minor bug fixes and updated pci.ids. (From OE-Core rev: bbda388857284612190b58abe8d73c93e39d1574) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
65 lines
2.0 KiB
BlitzBasic
65 lines
2.0 KiB
BlitzBasic
SUMMARY = "PCI utilities"
|
|
DESCRIPTION = 'The PCI Utilities package contains a library for portable access \
|
|
to PCI bus configuration space and several utilities based on this library.'
|
|
HOMEPAGE = "http://atrey.karlin.mff.cuni.cz/~mj/pciutils.shtml"
|
|
SECTION = "console/utils"
|
|
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
|
|
# Can drop make-native when all systems have make 4.3
|
|
# https://git.savannah.gnu.org/cgit/make.git/commit/?id=b90fabc8d6f34fb37d428dc0fb1b8b1951a9fbed
|
|
# causes space issues in lib/libpci.pc
|
|
DEPENDS = "zlib kmod make-native"
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/software/utils/pciutils/pciutils-${PV}.tar.xz \
|
|
file://configure.patch"
|
|
|
|
SRC_URI[sha256sum] = "3f472ad864473de5ba17f765cc96ef5f33e1b730918d3adda6f945a2a9290df4"
|
|
|
|
inherit multilib_header pkgconfig update-alternatives
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'hwdb', '', d)}"
|
|
PACKAGECONFIG[hwdb] = "HWDB=yes,HWDB=no,udev"
|
|
|
|
PCI_CONF_FLAG = "ZLIB=yes DNS=yes SHARED=yes STRIP= LIBDIR=${libdir}"
|
|
|
|
# see configure.patch
|
|
do_configure () {
|
|
(
|
|
cd lib && \
|
|
# PACKAGECONFIG_CONFARGS for this recipe could only possibly contain 'HWDB=yes/no',
|
|
# so we put it before ./configure
|
|
${PCI_CONF_FLAG} ${PACKAGECONFIG_CONFARGS} ./configure ${PV} ${datadir} ${TARGET_OS} ${TARGET_ARCH}
|
|
)
|
|
}
|
|
|
|
export PREFIX = "${prefix}"
|
|
export SBINDIR = "${sbindir}"
|
|
export SHAREDIR = "${datadir}"
|
|
export MANDIR = "${mandir}"
|
|
|
|
EXTRA_OEMAKE = "-e MAKEFLAGS= ${PCI_CONF_FLAG}"
|
|
|
|
ASNEEDED = ""
|
|
|
|
# The configure script breaks if the HOST variable is set
|
|
HOST[unexport] = "1"
|
|
|
|
do_install () {
|
|
oe_runmake DESTDIR=${D} install install-lib
|
|
|
|
install -d ${D}${bindir}
|
|
|
|
oe_multilib_header pci/config.h
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-ids libpci"
|
|
FILES:${PN}-ids = "${datadir}/pci.ids*"
|
|
FILES:libpci = "${libdir}/libpci.so.*"
|
|
SUMMARY:${PN}-ids = "PCI utilities - device ID database"
|
|
DESCRIPTION:${PN}-ids = "Package providing the PCI device ID database for pciutils."
|
|
RDEPENDS:${PN} += "${PN}-ids"
|
|
|
|
ALTERNATIVE:${PN} = "lspci"
|
|
ALTERNATIVE_PRIORITY = "100"
|