mirror of
https://git.yoctoproject.org/poky
synced 2026-02-15 13:13:02 +01:00
4ee082f60c
Fixed when len(TMPDIR) = 410: aclocal: error: cannot open echo [snip]: Argument list too long This is becuase it has a lot of m4 files, use relative path for them can fix the problem. It doesn't happen when MACHINE="qemux86", I think it is because intel-x86-64 is longer than qemux86. (From OE-Core rev: 5210ccd61ef52a191454a4587cfeb22079df746d) Signed-off-by: Robert Yang <liezhi.yang@windriver.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.2 KiB
BlitzBasic
41 lines
1.2 KiB
BlitzBasic
LICENSE = "GPLv3+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
require diffutils.inc
|
|
|
|
SRC_URI = "${GNU_MIRROR}/diffutils/diffutils-${PV}.tar.xz \
|
|
file://0001-Unset-need_charset_alias-when-building-for-musl.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
EXTRA_OECONF += "--without-libsigsegv-prefix"
|
|
|
|
# Fix "Argument list too long" error when len(TMPDIR) = 410
|
|
acpaths = "-I ./m4"
|
|
|
|
do_configure_prepend () {
|
|
# Need to remove gettext macros with weird mix of versions
|
|
for i in codeset.m4 gettext_gl.m4 intlmacosx.m4 inttypes-pri.m4 lib-ld_gl.m4 lib-prefix_gl.m4 po_gl.m4 ssize_t.m4 wchar_t.m4 wint_t.m4; do
|
|
rm -f ${S}/m4/$i
|
|
done
|
|
}
|
|
|
|
SRC_URI[md5sum] = "569354697ff1cfc9a9de3781361015fa"
|
|
SRC_URI[sha256sum] = "dad398ccd5b9faca6b0ab219a036453f62a602a56203ac659b43e889bec35533"
|
|
|
|
inherit ptest
|
|
|
|
do_install_ptest() {
|
|
t=${D}${PTEST_PATH}
|
|
install -D ${S}/build-aux/test-driver $t/build-aux/test-driver
|
|
cp -r ${S}/tests $t/
|
|
install ${B}/tests/Makefile $t/tests/
|
|
sed -e 's|^Makefile:|_Makefile:|' \
|
|
-e 's|bash|sh|' \
|
|
-e 's|^top_srcdir = \(.*\)|top_srcdir = ..\/|' \
|
|
-e 's|^srcdir = \(.*\)|srcdir = .|' \
|
|
-e 's|"`$(built_programs)`"|diff|' \
|
|
-e 's|gawk|awk|g' \
|
|
-i $t/tests/Makefile
|
|
}
|