mirror of
https://git.yoctoproject.org/poky
synced 2026-04-30 03:32:12 +02:00
b3bfb64529
(From OE-Core rev: 5933efd44811f97a53952dd72b6d2026ebfa8d39) Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
42 lines
1.7 KiB
BlitzBasic
42 lines
1.7 KiB
BlitzBasic
require sudo.inc
|
|
|
|
SRC_URI = "https://www.sudo.ws/dist/sudo-${PV}.tar.gz \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)} \
|
|
file://0001-Include-sys-types.h-for-id_t-definition.patch \
|
|
"
|
|
|
|
PAM_SRC_URI = "file://sudo.pam"
|
|
|
|
SRC_URI[md5sum] = "d56cd5835b1cc9852bd76ddaaa572475"
|
|
SRC_URI[sha256sum] = "a35ad3ddc7465703e04190d3ff0b8d78ded9246749becf9a014dcb9c31c579e7"
|
|
|
|
DEPENDS += " virtual/crypt ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
RDEPENDS_${PN} += " ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam-plugin-limits pam-plugin-keyinit', '', d)}"
|
|
|
|
EXTRA_OECONF += " \
|
|
ac_cv_type_rsize_t=no \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--with-pam', '--without-pam', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--enable-tmpfiles.d=${nonarch_libdir}/tmpfiles.d', '--disable-tmpfiles.d', d)} \
|
|
--with-vardir=/var/lib/sudo \
|
|
"
|
|
|
|
do_install_append () {
|
|
if [ "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}" ]; then
|
|
install -D -m 644 ${WORKDIR}/sudo.pam ${D}/${sysconfdir}/pam.d/sudo
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'pam-wheel', 'true', 'false', d)} ; then
|
|
echo 'auth required pam_wheel.so use_uid' >>${D}${sysconfdir}/pam.d/sudo
|
|
sed -i 's/# \(%wheel ALL=(ALL) ALL\)/\1/' ${D}${sysconfdir}/sudoers
|
|
fi
|
|
fi
|
|
|
|
chmod 4111 ${D}${bindir}/sudo
|
|
chmod 0440 ${D}${sysconfdir}/sudoers
|
|
|
|
# Explicitly remove the /run directory to avoid QA error
|
|
rmdir -p --ignore-fail-on-non-empty ${D}/run/sudo
|
|
}
|
|
|
|
FILES_${PN} += "${nonarch_libdir}/tmpfiles.d"
|
|
FILES_${PN}-dev += "${libexecdir}/${BPN}/lib*${SOLIBSDEV} ${libexecdir}/${BPN}/*.la \
|
|
${libexecdir}/lib*${SOLIBSDEV} ${libexecdir}/*.la"
|