mirror of
https://git.yoctoproject.org/poky
synced 2026-02-11 03:03:02 +01:00
52026492c6
With the addition of sstate, ensure that archiving tasks are only added to the build if they produce output in the directory specified by the 'sstate-inputdirs' flag. Move calls to 'tar_filter' and 'not_tarball' out to archive-*-source.bbclass in order to filter out packages before their archiving tasks are added to the build. Additionally, negate the return value of copyleft_should_include in tar_filter, so that packages that do not pass are in turn filtered out. (From OE-Core rev: 392562a21d9f2deb6fe6f8bb5378b09f4c5918d4) Signed-off-by: Kevin Strasser <kevin.strasser@linux.intel.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
72 lines
2.8 KiB
Plaintext
72 lines
2.8 KiB
Plaintext
# This file is for getting archiving packages with original
|
|
# sources(archive ${S} after unpack stage), patches, logs(archive 'temp'
|
|
# after package_write_rpm), dump data and creating diff file(get all
|
|
# environment variables and functions in building and mapping all
|
|
# content in ${S} including patches to xxx.diff.gz. All archived packages
|
|
# will be deployed in ${DEPLOY_DIR}/sources
|
|
|
|
inherit archiver
|
|
|
|
# Get original sources archiving package with patches
|
|
addtask do_archive_original_sources_patches after do_unpack
|
|
|
|
# Get archiving package with temp(logs) and scripts(.bb and inc files)
|
|
addtask do_archive_scripts_logs
|
|
|
|
# Get dump date and create diff file
|
|
addtask do_dumpdata_create_diff_gz
|
|
|
|
python () {
|
|
pn = d.getVar('PN', True)
|
|
packaging = d.getVar('IMAGE_PKGTYPE', True)
|
|
|
|
if tar_filter(d):
|
|
return
|
|
|
|
d.appendVarFlag('do_dumpdata_create_diff_gz', 'depends', ' %s:do_package_write_' %pn + packaging)
|
|
|
|
if d.getVar('SOURCE_ARCHIVE_PACKAGE_TYPE', True) != 'srpm':
|
|
"""
|
|
If package type is not 'srpm' then add tasks to move archive packages of
|
|
original sources and scripts/logs in ${DEPLOY_DIR}/sources.
|
|
"""
|
|
d.appendVarFlag('do_patch', 'depends', ' %s:do_archive_original_sources_patches' %pn)
|
|
build_deps = ' %s:do_dumpdata_create_diff_gz' %pn
|
|
if not not_tarball(d):
|
|
build_deps += ' %s:do_archive_original_sources_patches' %pn
|
|
if d.getVar('SOURCE_ARCHIVE_LOG_WITH_SCRIPTS', True) == 'logs_with_scripts':
|
|
build_deps += ' %s:do_archive_scripts_logs' %pn
|
|
d.appendVarFlag('do_archive_scripts_logs', 'depends', ' %s:do_package_write_' %pn + packaging)
|
|
d.appendVarFlag('do_build', 'depends', build_deps)
|
|
|
|
else:
|
|
d.prependVarFlag('do_unpack', 'postfuncs', "do_archive_original_sources_patches")
|
|
d.prependVarFlag('do_package_write_rpm', 'prefuncs', "do_archive_scripts_logs")
|
|
}
|
|
|
|
ARCHIVE_SSTATE_OUTDIR = "${DEPLOY_DIR}/sources/"
|
|
ARCHIVE_SSTATE_SCRIPTS_LOGS_INDIR = "${WORKDIR}/script-logs/"
|
|
ARCHIVE_SSTATE_DIFFGZ_ENVDATA_INDIR = "${WORKDIR}/diffgz-envdata/"
|
|
|
|
SSTATETASKS += "do_archive_scripts_logs"
|
|
do_archive_scripts_logs[sstate-name] = "archive_scripts_logs"
|
|
do_archive_scripts_logs[sstate-inputdirs] = "${ARCHIVE_SSTATE_SCRIPTS_LOGS_INDIR}"
|
|
do_archive_scripts_logs[sstate-outputdirs] = "${ARCHIVE_SSTATE_OUTDIR}"
|
|
|
|
python do_archive_scripts_logs_setscene () {
|
|
sstate_setscene(d)
|
|
}
|
|
|
|
addtask do_archive_scripts_logs_setscene
|
|
|
|
SSTATETASKS += "do_dumpdata_create_diff_gz"
|
|
do_dumpdata_create_diff_gz[sstate-name] = "dumpdata_create_diff_gz"
|
|
do_dumpdata_create_diff_gz[sstate-inputdirs] = "${ARCHIVE_SSTATE_DIFFGZ_ENVDATA_INDIR}"
|
|
do_dumpdata_create_diff_gz[sstate-outputdirs] = "${ARCHIVE_SSTATE_OUTDIR}"
|
|
|
|
python do_dumpdata_create_diff_gz_setscene () {
|
|
sstate_setscene(d)
|
|
}
|
|
|
|
addtask do_dumpdata_create_diff_gz_setscene
|