mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
51f694db18
- Refresh pkgconfig.patch (From OE-Core rev: 207112631575d5f85e57bc35dacc25fff768d280) Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
55 lines
1.9 KiB
BlitzBasic
55 lines
1.9 KiB
BlitzBasic
SUMMARY = "Small library that defines common error values for all GnuPG components"
|
|
DESCRIPTION = "Contains common error codes and error handling functions used by GnuPG, Libgcrypt, GPGME and more packages. "
|
|
HOMEPAGE = "http://www.gnupg.org/related_software/libgpg-error/"
|
|
BUGTRACKER = "https://bugs.g10code.com/gnupg/index"
|
|
|
|
LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
|
|
file://COPYING.LIB;md5=2d5025d4aa3495befef8f17206a5b0a1 \
|
|
file://src/gpg-error.h.in;beginline=2;endline=18;md5=badc79a9308e1cbd2657b2441c7cf017 \
|
|
file://src/init.c;beginline=2;endline=17;md5=f01cdfcf747af5380590cfd9bbfeaaf7 \
|
|
"
|
|
|
|
SECTION = "libs"
|
|
|
|
UPSTREAM_CHECK_URI = "https://gnupg.org/download/index.html"
|
|
SRC_URI = "${GNUPG_MIRROR}/libgpg-error/libgpg-error-${PV}.tar.bz2 \
|
|
file://pkgconfig.patch \
|
|
file://0001-Do-not-fail-when-testing-config-scripts.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "82c3d2deb4ad96ad3925d6f9f124fe7205716055ab50e291116ef27975d169c0"
|
|
|
|
BINCONFIG = "${bindir}/gpg-error-config"
|
|
|
|
inherit autotools binconfig-disabled pkgconfig gettext multilib_header multilib_script ptest
|
|
|
|
require recipes-support/gnupg/drop-unknown-suffix.inc
|
|
|
|
RDEPENDS:${PN}-ptest:append = " make bash"
|
|
|
|
MULTILIB_SCRIPTS = "${PN}-dev:${bindir}/gpgrt-config"
|
|
|
|
CPPFLAGS += "-P"
|
|
|
|
do_install:append() {
|
|
# we don't have common lisp in OE
|
|
rm -rf "${D}${datadir}/common-lisp/"
|
|
oe_multilib_header gpg-error.h gpgrt.h
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C tests buildtest-TESTS
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install ${B}/tests/t-*[!\.o] ${D}${PTEST_PATH}
|
|
install ${B}/tests/Makefile ${D}${PTEST_PATH}
|
|
}
|
|
|
|
FILES:${PN}-dev += "${bindir}/gpg-error"
|
|
FILES:${PN}-doc += "${datadir}/libgpg-error/errorref.txt"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|