mirror of
https://git.yoctoproject.org/poky
synced 2026-02-13 12:13:02 +01:00
bc9d2fbfd4
Original we used absolute path in sysroot-destdir for both native and target recipes. This commit changes target recipes to use relative path which is same as the image directory. [sgw: merged with libtool sysroot work] Signed-off-by: Dongxiao Xu <dongxiao.xu@intel.com> Signed-off-by: Saul Wold <sgw@linux.intel.com>
32 lines
1.1 KiB
BlitzBasic
32 lines
1.1 KiB
BlitzBasic
require libtool-${PV}.inc
|
|
|
|
PR = "r1"
|
|
PACKAGES = ""
|
|
SRC_URI += "file://prefix.patch"
|
|
|
|
do_configure_prepend () {
|
|
# Remove any existing libtool m4 since old stale versions would break
|
|
# any upgrade
|
|
rm -f ${STAGING_DATADIR}/aclocal/libtool.m4
|
|
rm -f ${STAGING_DATADIR}/aclocal/lt*.m4
|
|
}
|
|
|
|
do_install () {
|
|
install -d ${D}${bindir}/
|
|
install -m 0755 ${HOST_SYS}-libtool ${D}${bindir}/${HOST_SYS}-libtool
|
|
install -d ${D}${datadir}/libtool/
|
|
install -d ${D}${datadir}/aclocal/
|
|
install -c ${S}/libltdl/config/config.guess ${D}${datadir}/libtool/
|
|
install -c ${S}/libltdl/config/config.sub ${D}${datadir}/libtool/
|
|
install -c -m 0644 ${S}/libltdl/config/ltmain.sh ${D}${datadir}/libtool/
|
|
install -c -m 0644 ${S}/libltdl/m4/libtool.m4 ${D}${datadir}/aclocal/
|
|
install -c -m 0644 ${S}/libltdl/m4/ltdl.m4 ${D}${datadir}/aclocal/
|
|
}
|
|
|
|
SYSROOT_PREPROCESS_FUNCS += "libtoolcross_sysroot_preprocess"
|
|
|
|
libtoolcross_sysroot_preprocess () {
|
|
install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}
|
|
install -m 755 ${D}${bindir}/${HOST_SYS}-libtool ${SYSROOT_DESTDIR}${bindir_crossscripts}/${HOST_SYS}-libtool
|
|
}
|