mirror of
https://git.yoctoproject.org/poky
synced 2026-05-05 07:39:49 +02:00
820c10e689
Change all recipes to https where we get an http 301 permanent redirect. (From OE-Core rev: e514acda9e12bccde6d3974e0fd1a37b3837191a) Signed-off-by: Stefan Müller-Klieser <s.mueller-klieser@phytec.de> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
35 lines
1.2 KiB
BlitzBasic
35 lines
1.2 KiB
BlitzBasic
SUMMARY = "Power usage tool"
|
|
DESCRIPTION = "Linux tool to diagnose issues with power consumption and power management."
|
|
HOMEPAGE = "https://01.org/powertop/"
|
|
BUGTRACKER = "https://app.devzing.com/powertopbugs/bugzilla"
|
|
DEPENDS = "ncurses libnl pciutils"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e"
|
|
|
|
SRC_URI = "https://01.org/sites/default/files/downloads/powertop-v${PV}.tar.gz \
|
|
file://0001-wakeup_xxx.h-include-limits.h.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "a69bd55901cf919cc564187402ea2c9c"
|
|
SRC_URI[sha256sum] = "d3b7459eaba7d01c8841dd33a3b4d369416c01e9bd8951b0d88234cf18fe4a75"
|
|
|
|
UPSTREAM_CHECK_URI = "https://01.org/powertop/downloads"
|
|
UPSTREAM_CHECK_REGEX = "powertop-[v]?(?P<pver>\d+(\.\d+)+)\.tar"
|
|
|
|
inherit autotools gettext pkgconfig
|
|
|
|
S = "${WORKDIR}/${BPN}-v${PV}"
|
|
|
|
# we do not want libncursesw if we can
|
|
do_configure_prepend() {
|
|
# configure.ac checks for delwin() in "ncursesw ncurses" so let's drop first one
|
|
sed -i -e "s/ncursesw//g" ${S}/configure.ac
|
|
mkdir -p ${B}/src/tuning/
|
|
}
|
|
|
|
inherit update-alternatives
|
|
ALTERNATIVE_${PN} = "powertop"
|
|
ALTERNATIVE_TARGET[powertop] = "${sbindir}/powertop"
|
|
ALTERNATIVE_LINK_NAME[powertop] = "${sbindir}/powertop"
|
|
ALTERNATIVE_PRIORITY = "100"
|