mirror of
https://git.yoctoproject.org/poky
synced 2026-02-21 17:09:42 +01:00
b22e4f002d
Backport a patch to fix | ../git/util.cxx:1766:56: error: 'std::pointer_to_unary_function<_Arg, _Result> std::ptr_fun(_Result (*)(_Arg)) [with _Arg = int; _Result = int]' is deprecated: use 'std::function' instea d [-Werror=deprecated-declarations] | 1766 | std::not1(std::ptr_fun<int, int>(std::isspace)))); | | ~~~~~~~~~~~~~~~~~~~~~~^~~~~~~~~~~~~~ (From OE-Core rev: 18ae4fea4bf8681f9138d21124589918e336ff6b) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 0b360d12203aafd8bf96433d11221a6ed910a11f) Signed-off-by: Steve Sakoman <steve@sakoman.com>
72 lines
2.8 KiB
BlitzBasic
72 lines
2.8 KiB
BlitzBasic
SUMMARY = "Script-directed dynamic tracing and performance analysis tool for Linux"
|
|
DESCRIPTION = "It provides free software infrastructure to simplify the \
|
|
gathering of information about the running Linux system. This assists \
|
|
diagnosis of a performance or functional problem."
|
|
HOMEPAGE = "https://sourceware.org/systemtap/"
|
|
|
|
require systemtap_git.inc
|
|
|
|
SRC_URI += "file://0001-improve-reproducibility-for-c-compiling.patch \
|
|
file://0001-gcc12-c-compatibility-re-tweak-for-rhel6-use-functio.patch \
|
|
"
|
|
|
|
DEPENDS = "elfutils"
|
|
|
|
EXTRA_OECONF += "--with-libelf=${STAGING_DIR_TARGET} --without-rpm \
|
|
--without-nss --without-avahi --without-dyninst \
|
|
--disable-server --disable-grapher --enable-prologues \
|
|
--with-python3 --without-python2-probes \
|
|
ac_cv_prog_have_javac=no \
|
|
ac_cv_prog_have_jar=no "
|
|
|
|
STAP_DOCS ?= "--disable-docs --disable-publican --disable-refdocs"
|
|
|
|
EXTRA_OECONF += "${STAP_DOCS} "
|
|
|
|
PACKAGECONFIG ??= "translator sqlite monitor python3-probes"
|
|
PACKAGECONFIG[translator] = "--enable-translator,--disable-translator,boost,python3-core bash perl"
|
|
PACKAGECONFIG[libvirt] = "--enable-libvirt,--disable-libvirt,libvirt"
|
|
PACKAGECONFIG[sqlite] = "--enable-sqlite,--disable-sqlite,sqlite3"
|
|
PACKAGECONFIG[monitor] = "--enable-monitor,--disable-monitor,ncurses json-c"
|
|
PACKAGECONFIG[python3-probes] = "--with-python3-probes,--without-python3-probes,python3-setuptools-native"
|
|
|
|
inherit autotools gettext pkgconfig distutils3-base systemd
|
|
|
|
PACKAGES =+ "${PN}-exporter"
|
|
|
|
FILES_${PN}-exporter = "${sysconfdir}/stap-exporter/* \
|
|
${sysconfdir}/sysconfig/stap-exporter \
|
|
${systemd_unitdir}/system/stap-exporter.service \
|
|
${sbindir}/stap-exporter"
|
|
|
|
RDEPENDS_${PN}-exporter = "${PN} python3-core python3-netclient"
|
|
|
|
SYSTEMD_SERVICE_${PN}-exporter = "stap-exporter.service"
|
|
|
|
do_configure_prepend () {
|
|
# Improve reproducibility for c++ object files
|
|
reltivepath="${@os.path.relpath(d.getVar('STAGING_INCDIR'), d.getVar('S'))}"
|
|
sed -i "s:@RELATIVE_STAGING_INCDIR@:$reltivepath:g" ${S}/stringtable.h
|
|
}
|
|
|
|
do_install_append () {
|
|
if [ ! -f ${D}${bindir}/stap ]; then
|
|
# translator disabled case, need to leave only minimal runtime
|
|
rm -rf ${D}${datadir}/${PN}
|
|
rm ${D}${libexecdir}/${PN}/stap-env
|
|
fi
|
|
|
|
if [ ${D}${prefix}/lib != `dirname ${D}${systemd_unitdir}` ]; then
|
|
# Fix makefile hardcoded path assumptions for systemd (assumes $prefix)
|
|
# without usrmerge distro feature enabled
|
|
install -d `dirname ${D}${systemd_unitdir}`
|
|
mv ${D}${prefix}/lib/systemd `dirname ${D}${systemd_unitdir}`
|
|
rmdir ${D}${prefix}/lib --ignore-fail-on-non-empty
|
|
fi
|
|
|
|
# Ensure correct ownership for files copied in
|
|
chown root:root ${D}${sysconfdir}/stap-exporter/* -R
|
|
}
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|