mirror of
https://git.yoctoproject.org/poky
synced 2026-03-05 14:59:41 +01:00
aaaa25022b
--ignore-fail-on-non-empty is coreutils specific, and you are not always going to have coreutils on target systems especially small ones. They will use the busybox applet which does not support --ignore-fail-on-non-empty, use pipe and true to ignore the errorcode from rmdir instead Fixes upgrade errors on target e.g. rmdir: unrecognized option '--ignore-fail-on-non-empty' BusyBox v1.24.1 (2016-12-20 10:41:39 PST) multi-call binary. Usage: rmdir [OPTIONS] DIRECTORY... To remove package debris, try `opkg remove update-alternatives-opkg`. To re-attempt the install, try `opkg install update-alternatives-opkg`. Collected errors: * pkg_run_script: package "update-alternatives-opkg" postrm script returned status 1. * postrm_upgrade_old_pkg: postrm script for package "update-alternatives-opkg" failed (From OE-Core rev: 5ec8934a495e9b9a782889bc3a84936c8a381165) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
2.1 KiB
BlitzBasic
53 lines
2.1 KiB
BlitzBasic
SUMMARY = "Additional utilities for the opkg package manager"
|
|
SUMMARY_update-alternatives-opkg = "Utility for managing the alternatives system"
|
|
SECTION = "base"
|
|
HOMEPAGE = "http://git.yoctoproject.org/cgit/cgit.cgi/opkg-utils"
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
|
|
file://opkg.py;beginline=1;endline=18;md5=15917491ad6bf7acc666ca5f7cc1e083"
|
|
PROVIDES += "${@bb.utils.contains('PACKAGECONFIG', 'update-alternatives', 'virtual/update-alternatives', '', d)}"
|
|
|
|
SRCREV = "3ffece9bf19a844edacc563aa092fd1fbfcffeee"
|
|
PV = "0.3.2+git${SRCPV}"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/opkg-utils \
|
|
file://0001-update-alternatives-warn-when-multiple-providers-hav.patch"
|
|
SRC_URI_append_class-native = " file://tar_ignore_error.patch"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
TARGET_CC_ARCH += "${LDFLAGS}"
|
|
|
|
PYTHONRDEPS = "python python-shell python-io python-math python-crypt python-logging python-fcntl python-subprocess python-pickle python-compression python-textutils python-stringold"
|
|
PYTHONRDEPS_class-native = ""
|
|
|
|
PACKAGECONFIG = "python update-alternatives"
|
|
PACKAGECONFIG[python] = ",,,${PYTHONRDEPS}"
|
|
PACKAGECONFIG[update-alternatives] = ",,,"
|
|
|
|
do_install() {
|
|
oe_runmake PREFIX=${prefix} DESTDIR=${D} install
|
|
if ! ${@bb.utils.contains('PACKAGECONFIG', 'update-alternatives', 'true', 'false', d)}; then
|
|
rm -f "${D}${bindir}/update-alternatives"
|
|
fi
|
|
}
|
|
|
|
do_install_append_class-target() {
|
|
if [ -e "${D}${bindir}/update-alternatives" ]; then
|
|
sed -i ${D}${bindir}/update-alternatives -e 's,/usr/bin,${bindir},g; s,/usr/lib,${nonarch_libdir},g'
|
|
fi
|
|
}
|
|
|
|
PACKAGES =+ "update-alternatives-opkg"
|
|
FILES_update-alternatives-opkg = "${bindir}/update-alternatives"
|
|
RPROVIDES_update-alternatives-opkg = "update-alternatives update-alternatives-cworth"
|
|
RREPLACES_update-alternatives-opkg = "update-alternatives-cworth"
|
|
RCONFLICTS_update-alternatives-opkg = "update-alternatives-cworth"
|
|
|
|
pkg_postrm_update-alternatives-opkg() {
|
|
rm -rf $OPKG_OFFLINE_ROOT${nonarch_libdir}/opkg/alternatives
|
|
rmdir $OPKG_OFFLINE_ROOT${nonarch_libdir}/opkg || true
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|