mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
d97d3de1c4
E.g. if version is '43' without any dots, existing code would return ''. (From OE-Core rev: 38c15322bdbb2423973939e861b5ad1ffb5c8b7f) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
38 lines
1.0 KiB
Plaintext
38 lines
1.0 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
def gnome_verdir(v):
|
|
return ".".join(v.split(".")[:-1]) or v
|
|
|
|
|
|
GNOME_COMPRESS_TYPE ?= "xz"
|
|
SECTION ?= "x11/gnome"
|
|
GNOMEBN ?= "${BPN}"
|
|
SRC_URI = "${GNOME_MIRROR}/${GNOMEBN}/${@gnome_verdir("${PV}")}/${GNOMEBN}-${PV}.tar.${GNOME_COMPRESS_TYPE};name=archive"
|
|
|
|
FILES:${PN} += "${datadir}/application-registry \
|
|
${datadir}/mime-info \
|
|
${datadir}/mime/packages \
|
|
${datadir}/mime/application \
|
|
${datadir}/gnome-2.0 \
|
|
${datadir}/polkit* \
|
|
${datadir}/GConf \
|
|
${datadir}/glib-2.0/schemas \
|
|
${datadir}/appdata \
|
|
${datadir}/icons \
|
|
"
|
|
|
|
FILES:${PN}-doc += "${datadir}/devhelp"
|
|
|
|
GNOMEBASEBUILDCLASS ??= "autotools"
|
|
inherit ${GNOMEBASEBUILDCLASS} pkgconfig
|
|
|
|
do_install:append() {
|
|
rm -rf ${D}${localstatedir}/lib/scrollkeeper/*
|
|
rm -rf ${D}${localstatedir}/scrollkeeper/*
|
|
rm -f ${D}${datadir}/applications/*.cache
|
|
}
|