mirror of
https://git.yoctoproject.org/poky
synced 2026-02-08 18:02:12 +01:00
0c585f6b66
Add a patch to fix do_configure with GCC 14. Disable building cdda2wav because it doesn't build with GCC 14. (From OE-Core rev: 748d5f637f5aff3bc110b156cc3cb8e008f284c9) Signed-off-by: Zoltán Böszörményi <zboszor@gmail.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 0fbe1766abb00edeb8ec9a0c8bdb4e723be4f352) Signed-off-by: Steve Sakoman <steve@sakoman.com>
42 lines
1.4 KiB
BlitzBasic
42 lines
1.4 KiB
BlitzBasic
# cdrtools-native OE build file
|
|
# Copyright (C) 2004-2006, Advanced Micro Devices, Inc. All Rights Reserved
|
|
# Released under the MIT license (see packages/COPYING)
|
|
SUMMARY = "A set of tools for CD recording, including cdrecord"
|
|
HOMEPAGE = "http://sourceforge.net/projects/cdrtools/"
|
|
DESCRIPTION = "cdrecord tool is Highly portable CD/DVD/BluRay command line recording software."
|
|
SECTION = "console/utils"
|
|
LICENSE = "GPL-2.0-only & CDDL-1.0 & LGPL-2.1-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=32f68170be424c2cd64804337726b312"
|
|
|
|
DEPENDS += "gnu-config-native"
|
|
|
|
SRC_URI = " \
|
|
${SOURCEFORGE_MIRROR}/project/cdrtools/cdrtools-${PV}.tar.bz2 \
|
|
file://0001-Don-t-set-uid-gid-during-install.patch \
|
|
file://riscv64-linux-gcc.rul \
|
|
file://gcc14-fix.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "7d45c5b7e1f78d85d1583b361aee6e8b"
|
|
SRC_URI[sha256sum] = "ed282eb6276c4154ce6a0b5dee0bdb81940d0cbbfc7d03f769c4735ef5f5860f"
|
|
|
|
EXTRA_OEMAKE = "-e MAKEFLAGS="
|
|
|
|
# Stop failures when 'cc' can't be found
|
|
export ac_cv_prog_CC = "${CC}"
|
|
|
|
inherit native
|
|
|
|
do_configure() {
|
|
# cdda2wav does not build with GCC 14
|
|
rm -f ${S}/TARGETS/55cdda2wav
|
|
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}/autoconf
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}/autoconf
|
|
install -m 0644 ${WORKDIR}/riscv64-linux-gcc.rul ${S}/RULES/
|
|
}
|
|
|
|
do_install() {
|
|
make install GMAKE_NOWARN=true INS_BASE=${prefix} DESTDIR=${D}
|
|
}
|