mirror of
https://git.yoctoproject.org/poky
synced 2026-03-02 05:19:40 +01:00
11ed2d14f9
Upstream maintainer has changed to Chen-Yu Tsai <wens@kernel.org>: https://lore.kernel.org/all/CAGb2v657baNMPKU3QADijx7hZa=GUcSv2LEDdn6N=QQaFX8r-g@mail.gmail.com/ Note that fb768d3b13ff ("wifi: cfg80211: Add my certificate") and 3c2a8ebe3fe6 ("wifi: cfg80211: fix certs build to not depend on file order") are required if you are using kernel signature verification. (From OE-Core rev: abf169fbbf8bab13224adf4c8bfa2e26607f360c) Signed-off-by: Alex Kiernan <alex.kiernan@gmail.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
44 lines
1.6 KiB
BlitzBasic
44 lines
1.6 KiB
BlitzBasic
SUMMARY = "Wireless Central Regulatory Domain Database"
|
|
HOMEPAGE = "https://wireless.wiki.kernel.org/en/developers/regulatory/crda"
|
|
SECTION = "net"
|
|
LICENSE = "ISC"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=07c4f6dea3845b02a18dc00c8c87699c"
|
|
|
|
SRC_URI = "https://www.kernel.org/pub/software/network/${BPN}/${BP}.tar.xz"
|
|
SRC_URI[sha256sum] = "c8a61c9acf76fa7eb4239e89f640dee3e87098d9f69b4d3518c9c60fc6d20c55"
|
|
|
|
inherit bin_package allarch
|
|
|
|
do_install() {
|
|
install -d -m0755 ${D}${nonarch_libdir}/crda
|
|
install -d -m0755 ${D}${sysconfdir}/wireless-regdb/pubkeys
|
|
install -m 0644 regulatory.bin ${D}${nonarch_libdir}/crda/regulatory.bin
|
|
install -m 0644 wens.key.pub.pem ${D}${sysconfdir}/wireless-regdb/pubkeys/wens.key.pub.pem
|
|
|
|
install -m 0644 -D regulatory.db ${D}${nonarch_base_libdir}/firmware/regulatory.db
|
|
install -m 0644 regulatory.db.p7s ${D}${nonarch_base_libdir}/firmware/regulatory.db.p7s
|
|
}
|
|
|
|
# Install static regulatory DB in /lib/firmware for kernel to load.
|
|
# This requires Linux kernel >= v4.15.
|
|
# For kernel <= v4.14, inherit the kernel_wireless_regdb.bbclass
|
|
# (in meta-networking) in kernel's recipe.
|
|
PACKAGES = "${PN}-static ${PN}"
|
|
RCONFLICTS:${PN} = "${PN}-static"
|
|
|
|
FILES:${PN}-static = " \
|
|
${nonarch_base_libdir}/firmware/regulatory.db \
|
|
${nonarch_base_libdir}/firmware/regulatory.db.p7s \
|
|
"
|
|
|
|
# Native users might want to use the source of regulatory DB.
|
|
# This is for example used by Linux kernel <= v4.14 and
|
|
# kernel_wireless_regdb.bbclass in meta-networking.
|
|
do_install:append:class-native() {
|
|
install -m 0644 -D db.txt ${D}${libdir}/crda/db.txt
|
|
}
|
|
|
|
RSUGGESTS:${PN} = "crda"
|
|
|
|
BBCLASSEXTEND = "native"
|