mirror of
https://git.yoctoproject.org/poky
synced 2026-03-31 11:02:21 +02:00
1e4c6e8f2e
Backports from upstream:d34e00b2933460dc486dExpected to be released officially as part of strace 4.11 (From OE-Core rev: 7d40c6ff1d1d64ebeeffb6bfc200dcd84861214a) Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
49 lines
1.5 KiB
BlitzBasic
49 lines
1.5 KiB
BlitzBasic
SUMMARY = "System call tracing tool"
|
|
HOMEPAGE = "http://strace.sourceforge.net"
|
|
SECTION = "console/utils"
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=124500c21e856f0912df29295ba104c7"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/strace/strace-${PV}.tar.xz \
|
|
file://0001-Add-linux-aarch64-arch_regs.h.patch \
|
|
file://git-version-gen \
|
|
file://strace-add-configure-options.patch \
|
|
file://Makefile-ptest.patch \
|
|
file://run-ptest \
|
|
file://Include-sys-stat.h-for-S_I-macros.patch \
|
|
file://Include-linux-ioctl.h-for-_IOC_-macros.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "107a5be455493861189e9b57a3a51912"
|
|
SRC_URI[sha256sum] = "e6180d866ef9e76586b96e2ece2bfeeb3aa23f5cc88153f76e9caedd65e40ee2"
|
|
|
|
inherit autotools ptest
|
|
RDEPENDS_${PN}-ptest += "make coreutils grep gawk"
|
|
|
|
PACKAGECONFIG_class-target ?= "libaio ${@bb.utils.contains('DISTRO_FEATURES', 'acl', 'acl', '', d)}"
|
|
|
|
PACKAGECONFIG[libaio] = "--enable-aio,--disable-aio,libaio"
|
|
PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl"
|
|
PACKAGECONFIG[libunwind] = "--with-libunwind, --without-libunwind, libunwind"
|
|
|
|
TESTDIR = "tests"
|
|
|
|
do_configure_prepend() {
|
|
cp ${WORKDIR}/git-version-gen ${S}
|
|
}
|
|
|
|
do_install_append() {
|
|
# We don't ship strace-graph here because it needs perl
|
|
rm ${D}${bindir}/strace-graph
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C ${TESTDIR} buildtest-TESTS OS=linux ARCH="${TARGET_ARCH}"
|
|
}
|
|
|
|
do_install_ptest() {
|
|
oe_runmake -C ${TESTDIR} install-ptest BUILDDIR=${B} DESTDIR=${D}${PTEST_PATH} TESTDIR=${TESTDIR}
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|