mirror of
https://git.yoctoproject.org/poky
synced 2026-02-20 16:39:40 +01:00
f1a5c7c53b
Note that this just removes a host path leakage: diffutils still doesn't depend on coreutils so 'pr' might not actually be there on image (this only breaks "diff -l" so no big deal). (From OE-Core rev: 3f7fd738981752a8c34c6cf4a1f2d4c035b081ca) Signed-off-by: Jussi Kukkonen <jussi.kukkonen@intel.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.3 KiB
BlitzBasic
41 lines
1.3 KiB
BlitzBasic
LICENSE = "GPLv3+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
require diffutils.inc
|
|
|
|
SRC_URI = "${GNU_MIRROR}/diffutils/diffutils-${PV}.tar.xz \
|
|
file://0001-Unset-need_charset_alias-when-building-for-musl.patch \
|
|
file://diffutils-3.5-gcc7.patch \
|
|
file://run-ptest \
|
|
"
|
|
SRC_URI[md5sum] = "569354697ff1cfc9a9de3781361015fa"
|
|
SRC_URI[sha256sum] = "dad398ccd5b9faca6b0ab219a036453f62a602a56203ac659b43e889bec35533"
|
|
|
|
EXTRA_OECONF += "ac_cv_path_PR_PROGRAM=${bindir}/pr --without-libsigsegv-prefix"
|
|
|
|
# Fix "Argument list too long" error when len(TMPDIR) = 410
|
|
acpaths = "-I ./m4"
|
|
|
|
do_configure_prepend () {
|
|
# Need to remove gettext macros with weird mix of versions
|
|
for i in codeset.m4 gettext_gl.m4 intlmacosx.m4 inttypes-pri.m4 lib-ld_gl.m4 lib-prefix_gl.m4 po_gl.m4 ssize_t.m4 wchar_t.m4 wint_t.m4; do
|
|
rm -f ${S}/m4/$i
|
|
done
|
|
}
|
|
|
|
inherit ptest
|
|
|
|
do_install_ptest() {
|
|
t=${D}${PTEST_PATH}
|
|
install -D ${S}/build-aux/test-driver $t/build-aux/test-driver
|
|
cp -r ${S}/tests $t/
|
|
install ${B}/tests/Makefile $t/tests/
|
|
sed -e 's|^Makefile:|_Makefile:|' \
|
|
-e 's|bash|sh|' \
|
|
-e 's|^top_srcdir = \(.*\)|top_srcdir = ..\/|' \
|
|
-e 's|^srcdir = \(.*\)|srcdir = .|' \
|
|
-e 's|"`$(built_programs)`"|diff|' \
|
|
-e 's|gawk|awk|g' \
|
|
-i $t/tests/Makefile
|
|
}
|