mirror of
https://git.yoctoproject.org/poky
synced 2026-04-27 03:32:12 +02:00
5505bde50f
This helps in compiling other programs like expect which depend on private headers but 8.5, 8.6 and so on is enough granularity and currently we had 8.6.x and so on which means that expect recipe will need to be touched whenever there is minor update of tcl. Additionally the encode creating symlink to shared object in patch and remove it from recipe Refresh patches after making changes to Configure.in we propertly generate configure and not patch is directly as was the case. (From OE-Core rev: 67f44193135c789e478410347ff58ed110ed9484) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
79 lines
2.4 KiB
BlitzBasic
79 lines
2.4 KiB
BlitzBasic
DESCRIPTION = "Tool Command Language"
|
|
LICENSE = "BSD-3-Clause"
|
|
SECTION = "devel/tcltk"
|
|
HOMEPAGE = "http://tcl.sourceforge.net"
|
|
DEPENDS = "tcl-native zlib"
|
|
LIC_FILES_CHKSUM = "file://../license.terms;md5=3c6f62c07835353e36f0db550ccfb65a \
|
|
file://../compat/license.terms;md5=3c6f62c07835353e36f0db550ccfb65a \
|
|
file://../library/license.terms;md5=3c6f62c07835353e36f0db550ccfb65a \
|
|
file://../macosx/license.terms;md5=3c6f62c07835353e36f0db550ccfb65a \
|
|
file://../tests/license.terms;md5=3c6f62c07835353e36f0db550ccfb65a \
|
|
file://../win/license.terms;md5=3c6f62c07835353e36f0db550ccfb65a \
|
|
"
|
|
|
|
BASE_SRC_URI = "${SOURCEFORGE_MIRROR}/tcl/tcl${PV}-src.tar.gz \
|
|
file://tcl-add-soname.patch"
|
|
|
|
SRC_URI = "${BASE_SRC_URI} \
|
|
file://fix_non_native_build_issue.patch \
|
|
file://fix_issue_with_old_distro_glibc.patch \
|
|
file://no_packages.patch \
|
|
file://tcl-remove-hardcoded-install-path.patch \
|
|
file://alter-includedir.patch \
|
|
"
|
|
SRC_URI[md5sum] = "aae4b701ee527c6e4e1a6f9c7399882e"
|
|
SRC_URI[sha256sum] = "16ee769248e64ba1cae6b4834fcc4e4edd7470d881410e8d58f7dd1434343514"
|
|
|
|
SRC_URI_class-native = "${BASE_SRC_URI}"
|
|
|
|
S = "${WORKDIR}/tcl${PV}/unix"
|
|
|
|
VER = "8.6"
|
|
|
|
inherit autotools
|
|
|
|
DEPENDS_class-native = ""
|
|
|
|
EXTRA_OECONF = "--enable-threads --disable-rpath"
|
|
|
|
do_configure() {
|
|
( cd ${S}; gnu-configize )
|
|
oe_runconf
|
|
}
|
|
|
|
do_compile_prepend() {
|
|
echo > ${S}/../compat/fixstrtod.c
|
|
}
|
|
|
|
do_install() {
|
|
autotools_do_install install-private-headers
|
|
ln -sf ./tclsh${VER} ${D}${bindir}/tclsh
|
|
sed -i "s+${WORKDIR}+${STAGING_INCDIR}+g" tclConfig.sh
|
|
sed -i "s,-L${libdir},-L=${libdir},g" tclConfig.sh
|
|
sed -i "s,-I${includedir},-I=${includedir},g" tclConfig.sh
|
|
install -d ${D}${bindir_crossscripts}
|
|
install -m 0755 tclConfig.sh ${D}${bindir_crossscripts}
|
|
cd ..
|
|
for dir in compat generic unix
|
|
do
|
|
install -d ${D}${includedir}/${BPN}${VER}/$dir
|
|
install -m 0644 ${S}/../$dir/*.h ${D}${includedir}/${BPN}${VER}/$dir/
|
|
done
|
|
}
|
|
|
|
SYSROOT_PREPROCESS_FUNCS += "tcl_sysroot_preprocess"
|
|
tcl_sysroot_preprocess () {
|
|
sysroot_stage_dir ${D}${bindir_crossscripts} ${SYSROOT_DESTDIR}${bindir_crossscripts}
|
|
}
|
|
|
|
PACKAGES =+ "tcl-lib"
|
|
FILES_tcl-lib = "${libdir}/libtcl${VER}.so.*"
|
|
FILES_${PN} += "${libdir}/tcl${VER} ${libdir}/tcl8"
|
|
FILES_${PN}-dev += "${libdir}/tclConfig.sh ${libdir}/tclooConfig.sh"
|
|
|
|
# isn't getting picked up by shlibs code
|
|
RDEPENDS_${PN} += "tcl-lib"
|
|
RDEPENDS_${PN}_class-native = ""
|
|
|
|
BBCLASSEXTEND = "native"
|