mirror of
https://git.yoctoproject.org/poky
synced 2026-02-20 08:29:42 +01:00
43cdee3282
Added HOMEPAGE and DESCRIPTION for recipes with missing decriptions or homepage [YOCTO #13471] (From OE-Core rev: bd3352880322598b0ba6dc439ff08c2e4c592e36) Signed-off-by: Dorinda Bassey <dorindabassey@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit bb05814335e7101bfd8df0a11dc18a044e867bed) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
35 lines
1.3 KiB
BlitzBasic
35 lines
1.3 KiB
BlitzBasic
SUMMARY = "Utility for modifying GPT disk partitioning"
|
|
DESCRIPTION = "GPT fdisk is a disk partitioning tool loosely modeled on Linux fdisk, but used for modifying GUID Partition Table (GPT) disks. The related FixParts utility fixes some common problems on Master Boot Record (MBR) disks."
|
|
HOMEPAGE = "https://sourceforge.net/projects/gptfdisk/"
|
|
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552"
|
|
|
|
DEPENDS = "util-linux"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/${BPN}/${PV}/${BP}.tar.gz"
|
|
SRC_URI[md5sum] = "5ecc3c44913bb6b53d3708d1ac7ac295"
|
|
SRC_URI[sha256sum] = "b663391a6876f19a3cd901d862423a16e2b5ceaa2f4a3b9bb681e64b9c7ba78d"
|
|
|
|
UPSTREAM_CHECK_URI = "http://sourceforge.net/projects/gptfdisk/files/gptfdisk/"
|
|
UPSTREAM_CHECK_REGEX = "/gptfdisk/(?P<pver>(\d+[\.\-_]*)+)/"
|
|
|
|
EXTRA_OEMAKE = "'CC=${CC}' 'CXX=${CXX}' gdisk fixparts ${PACKAGECONFIG_CONFARGS}"
|
|
|
|
PACKAGECONFIG ??= "ncurses popt"
|
|
PACKAGECONFIG[ncurses] = "cgdisk,,ncurses"
|
|
PACKAGECONFIG[popt] = "sgdisk,,popt"
|
|
|
|
do_install() {
|
|
install -d ${D}${sbindir}
|
|
for f in cgdisk sgdisk; do
|
|
if [ -x $f ]; then
|
|
install -m 0755 $f ${D}${sbindir}
|
|
fi
|
|
done
|
|
install -m 0755 gdisk ${D}${sbindir}
|
|
install -m 0755 fixparts ${D}${sbindir}
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|