mirror of
https://git.yoctoproject.org/poky
synced 2026-02-24 10:29:40 +01:00
c95dec0b93
It moved from meta-oe and fixed the defect that xmlto/xsltproc stylesheets cannot be found even when they are installed in sysroot. About the config files (catalog.xml), we refered what Ubuntu 13.04 did, so it could correctly search the xsl stylesheets and xml dtds. Assigned the environment variable XML_CATALOG_FILES, so the xmlto will use oe-core's config as priority to avoid the the search from build system. [YOCTO #2416] (From OE-Core rev: 6eccf7940e90dd06568f7a2da36ce2d5d090aed5) Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
38 lines
1.2 KiB
BlitzBasic
38 lines
1.2 KiB
BlitzBasic
SUMMARY = "A shell-script tool for converting XML files to various formats"
|
|
HOMEPAGE = "https://fedorahosted.org/xmlto/"
|
|
SECTION = "docs/xmlto"
|
|
LICENSE = "GPLv2"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552"
|
|
|
|
SRC_URI = "https://fedorahosted.org/releases/x/m/xmlto/xmlto-${PV}.tar.gz \
|
|
file://obsolete_automake_macros.patch \
|
|
file://configure.in-drop-the-test-of-xmllint-and-xsltproc.patch \
|
|
file://catalog.xml \
|
|
"
|
|
SRC_URI[md5sum] = "a88cd3f08789b4825d1ac89fa065170d"
|
|
SRC_URI[sha256sum] = "c52b56d929e8d20fc19cd3b7ec238f8d039730c56ee311cc352e843147e3e31a"
|
|
|
|
inherit autotools
|
|
|
|
# xmlto needs getopt/xmllint/xsltproc at runtime
|
|
RDEPENDS_${PN} = "docbook-xml-dtd4 \
|
|
docbook-xsl-stylesheets \
|
|
util-linux \
|
|
libxml2 \
|
|
"
|
|
RDEPENDS_${PN}_append_class-target = " \
|
|
libxslt-bin \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native"
|
|
|
|
EXTRA_OECONF_append = " XMLLINT=xmllint XSLTPROC=xsltproc"
|
|
|
|
do_install_append() {
|
|
install -d ${D}${sysconfdir}/xml/
|
|
install -m 755 ${WORKDIR}/catalog.xml ${D}${sysconfdir}/xml/catalog.xml
|
|
create_wrapper ${D}/${bindir}/xmlto XML_CATALOG_FILES=${sysconfdir}/xml/catalog.xml
|
|
}
|
|
|